当前位置: 主页 > 期货交易技巧 >
栏目导航

博易大师指标公式大全

时间:2019-05-28 14:07来源:操盘手联盟 作者:diqib 点击:
博易大师指标公式大全 函数 功能 解释 示例 即时行情 DYNAINFO(02) 昨结算价 取得动态行情:昨结算价 DYNAINFO(03) 昨收价 取得动态行情:昨收价 DYNAINFO(04) 今开价 取得动态行情:今开价 DYNAINFO(05) 最高价 取得动态行情:最高价 DYNAINFO(06) 最低价
博易大师指标公式大全
 
函数 功能 解释 示例
即时行情
DYNAINFO(02) 昨结算价 取得动态行情:昨结算价
DYNAINFO(03) 昨收价 取得动态行情:昨收价
DYNAINFO(04) 今开价 取得动态行情:今开价
DYNAINFO(05) 最高价 取得动态行情:最高价
DYNAINFO(06) 最低价 取得动态行情:最低价
DYNAINFO(07) 最新价 取得动态行情:最新价
DYNAINFO(08) 总成交量 取得动态行情:总成交量
DYNAINFO(09) 最新成交量 取得动态行情:最新成交量
DYNAINFO(10)  总成交金额 取得动态行情:总成交金额
DYNAINFO(11) 均价 取得动态行情:均价
DYNAINFO(12) 涨跌 取得动态行情:涨跌
DYNAINFO(13) 振幅 取得动态行情:振幅
DYNAINFO(14) 涨幅 取得动态行情:涨幅
DYNAINFO(15) 委比 取得动态行情:委比
DYNAINFO(16) 委差 取得动态行情:委差
DYNAINFO(17) 量比 取得动态行情:量比
DYNAINFO(22) 内盘 取得动态行情:内盘
DYNAINFO(23) 外盘 取得动态行情:外盘
DYNAINFO(24) 涨速 取得动态行情:涨速
DYNAINFO(25) 换手率 取得动态行情:换手率
DYNAINFO(26) 5天均量 取得动态行情:5日均量
DYNAINFO(27) 动态市盈率 取得动态行情:动态市盈率
DYNAINFO(41) 委买量一 取得动态行情:委买量一
DYNAINFO(42) 委买量二 取得动态行情:委买量二
DYNAINFO(43) 委买量三 取得动态行情:委买量三
DYNAINFO(44) 委买量四 取得动态行情:委买量四
DYNAINFO(45) 委买量五 取得动态行情:委买量五
DYNAINFO(51) 委买价一 取得动态行情:委买价一
DYNAINFO(52) 委买价二 取得动态行情:委买价二
DYNAINFO(53) 委买价三 取得动态行情:委买价三
DYNAINFO(54)  委买价四 取得动态行情:委买价四
DYNAINFO(55) 委买价五 取得动态行情:委买价五
DYNAINFO(61) 委卖量一 取得动态行情:委卖量一
DYNAINFO(62) 委卖量二 取得动态行情:委卖量二
DYNAINFO(63) 委卖量三 取得动态行情:委卖量三
DYNAINFO(64) 委卖量四 取得动态行情:委卖量四
DYNAINFO(65) 委卖量五 取得动态行情:委卖量五
函数 功能 解释 示例
即时行情
DYNAINFO(71) 委卖价一 取得动态行情:委卖价一
DYNAINFO(72) 委卖价二 取得动态行情:委卖价二
DYNAINFO(73) 委卖价三 取得动态行情:委卖价三
DYNAINFO(74) 委卖价四 取得动态行情:委卖价四
DYNAINFO(75) 委卖价五 取得动态行情:委卖价五
 
函数 功能 解释 示例
即时行情
DYNAINFO2 跨品种动态行情 DYNAINFO2(Index,Code)
取指定品种对应序号Index的动态行情数据。Index为行情序号,顺序同DYNAINFO;Code为品种代码,当代码为常量时,可以动态更新该品种数据,否则只能使用本地最近保存的数据。 DYNAINFO2(14,'000001.SH'),表示上证指数的最新涨幅;
DYNAINFO2(03,'CU1101'),表示沪铜1101合约的昨收价。
 
基础信息
BONDSINFO(01) 债券全称 取得债券信息:债券全称
BONDSINFO(02) 发行日期 取得债券信息:发行日期
BONDSINFO(03) 开始计息日 取得债券信息:开始计息日
BONDSINFO(04) 到期日 取得债券信息:到期日
BONDSINFO(05) 剩余期限 取得债券信息:剩余期限
BONDSINFO(06) 发行价 取得债券信息:发行价
BONDSINFO(07) 面额 取得债券信息:面额
BONDSINFO(08) 票面利率 取得债券信息:票面利率
BONDSINFO(09) 到期天数 取得债券信息:到期天数
BONDSINFO(10) 付息方式 取得债券信息:付息方式0-贴现1-到期还本付息2-多次付息
BONDSINFO(11) 每年付息频率 取得每年付息频率,对“付息方式”为“多次付息”的债券有效
BONDSINFO(23) 市场修正久期 取得债券信息:市场修正久期
BONDSINFO(24) 市场凸性 取得债券信息:市场凸性
BONDSINFO(25) 市场基点价值 取得债券信息:市场基点价值
BONDSINFO(32) 估价收益率(%) 取得债券信息:估价收益率(%)
BONDSINFO2 跨品种债券信息
BONDSINFO2(Index,Code)
取指定品种对应序号Index的债券信息数据。Index为数据序号,顺序同BONDSINFO;Code为债券代码。 BONDSINFO2(04,'010107.SH'),表示上证所21国债(7)的到期日。
 
 
 
 
函数 功能 解释 示例
基础财务
CAPITAL 流通股本 取得流通股本。
同FINANCE(06)。
CONVERFACTOR(Code) 转换因子
国债现券对应国债期货合约的转换因子。Code为国债期货合约代码 CONVERFACTOR('TF1512.ZJS')
CONVERFACTOR2(Code1,Code2) 跨品种转换因子
指定国债现券对应国债期货合约的转换因子。
Code1为国债现券代码
Code2为国债期货合约代码
CONVERFACTOR2('019401.SH', 'TF1512.ZJS')
FINANCE(01) 净资产 每股净资产 适用于股票,下同
FINANCE(02) 去年每股收益 上年度每股收益
FINANCE(03) 预计每股收益 预计本年度每股收益
FINANCE(04) 净利润 基础财务:净利润
FINANCE(05) 总股本 基础财务:总股本
FINANCE(06) 流通股本 基础财务:流通股本
FINANCE(07) 总资产 基础财务:总资产
FINANCE(08) 总负债 基础财务:总负债
FINANCE2(Index,Code) 跨品种基础财务
取指定品种对应序号Index的基础财务数据。Index为数据序号,顺序同FINANCE;
Code为证券代码。 例如:FINANCE2(07,'000001.SZ'),表示深发展A的总资产。
 
 
函数 功能 解释 示例
期权信息
OPTIONINFO(01) 标的合约
OPTIONINFO(02) 期权类型 返回整数。0-股票期权,1-股指期权,2-期货期权。
OPTIONINFO(03) 行权方式 返回整数。0-欧式,1-美式。
OPTIONINFO(04) 期权方向 返回整数。0-认购(看涨)期权,1-认沽(看跌)期权
OPTIONINFO(05) 行权价格
OPTIONINFO(06) 行权比例
OPTIONINFO(07) 最后交易日
OPTIONINFO(08) 距交易到期天数 返回天数为交易天数,不包括周末和节假日。
OPTIONINFO(09) 行权起始日
OPTIONINFO2
跨品种 OPTIONINFO2(Index,Code)取指定品种对应序号Index的期权基础信息。Index为数据序号,顺序同OPTIONINFO;Code为期权合约代码。 OPTIONINFO2(01,'10000001.SH'),表示上交所10000001期权的标的股票。
 
函数 功能 解释 示例
主力资金
FLZJ(Side,Attr,Index) 主力资金 取由参数指定的分类主力资金数据细项。Side为买卖方向:0-买,1-卖;Attr为资金分层:0-庄单,1-大单,2-中单,3-小单;Index为数据类型:0-累计成交量,1-累计成交金额,2-累计成交笔数。 FLZJ(0, 0, 0),表示庄单累计买入量。
ZLJZ 当前股票主力流入净值 取当前股票当前周期主力流入净值
ZLJZ2(Code) 指定股票主力流入净值 取指定股票当前周期主力流入净值。
Code为证券代码,当代码为常量时,可以动态更新该品种数据,否则只能使用本地最近保存的数据。 ZLJZ2('600000.SH'),表示引用浦发银行的主力净值。
 
函数 功能 解释 示例
历史行情
ADVANCE 上涨家数 取当前周期上涨家数 注意:该函数适用于指数行情
AMOUNT 持仓量 取当前周期持仓量 注意:该函数适用于期货行情
BONDYIELD 债券到期收益率 取当前周期的债券到期收益率(%) 注意:该函数适用于债券品种。
BUYVOL 外盘量。 取当前周期外盘量(主动买量)
C 收盘价 取当前周期收盘价。同CLOSE
CLOSE 收盘价 取当前周期收盘价。简写为:C
DATACOUNT 总周期数 取总周期数
DECLINE 下跌家数 取当前周期下跌家数 注意:该函数适用于指数行情
H 最高价 取当前周期最高价,同HIGH
HIGH 最高价 取当前周期最高价。简写为:H
HISEXPDATE 合约最后交易日 取当前周期期货合约的最后交易日
注意:该函数仅适用于期货品种 DATE<HISEXPDATE OR
NOT(HISEXPDATE)。可限制仅在最后交易日前交易
HISEXPDAYS 合约距交割日的天数 取当前周期期货合约距离最后交易日的天数。注意:该函数仅适用于期货品种 同上:限制仅在交割日前交易
DATE+HISEXPDAYS<HISEXPDATE
ISDOWN 是否阴线 判断当前周期是否下跌
ISEQUAL 是否十字线 判断当前周期是否平盘
ISUP 是否阳线 判断当前周期是否上涨
L 最低价 取当前周期最低价。同LOW
LOW 最低价 取当前周期最低价。简写为:L
O 开盘价 取当前周期开盘价。同OPEN
OPEN 开盘价 取当前周期开盘价。简写为O
SELLVOL 内盘量 取当前周期内盘量(主动卖量)
SETTLEPRICE 结算价 取当前周期结算价
注意:该函数适用于期货行情
TURNOVER 成交金额 取当前周期成交金额
V 成交量 取当前周期成交量。同VOL
VOL 成交量 取当前周期成交量。简写为:V
ZBS 成交总笔数 取当前周期成交总笔数
 
函数 功能 解释 示例
专业财务
 
 
扩展数据
 
 
数据引用
ALTFILTER(X1,X2) 交换信号过滤 X1与X2信号交替过滤
第一次出现满足X1或X2时,设置该周期数值为1,此后直到出现不同信号时设置该信号周期数值为1,否则设置数值为0,依此方法过滤所有信号。 ALTFILTER(MA(C,5)>MA(C,10),MA(C,5)<MA(C,10))。
表示寻找5日收盘均线和10日收盘均线的交叉点。
BACKSET(X,N) 向前赋值 满足X时,设置当前周期到N周期前的数值为1;否则设置当前周期为0。
BACKSET(LOW>REF(HIGH,1),2)。表示当前周期最低价高于前一周期最高价时,最近两个周期结果设置为1,否则当前周期设置为0。
FILTER(X,N) 信号过滤 当条件X成立时,返回1并将接下来N周期的数值置0;否则返回0。 FILTER(CLOSE>OPEN,5)。表示查找阳线,5天内再次出现的阳线不被记录在内。
REF(X,N) 向前引用 引用N周期前的X值。 REF(CLOSE,1)。表示前一周期收盘价。
REFX(X,N) 向后引用 引用N周期后的X值。 REFX(CLOSE,1)。表示后一周期收盘价。
STKCALC(Code,Period,'Expr') 跨品种、周期计算 引用指定品种指定周期的脚本计算结果
Code为品种代码,当代码为常量时,可以动态更新该品种数据,否则只能使用本地最近保存的数据。Period为周期类型,取值参考DATAPERIOD;Expr为脚本公式,建议为简短的脚本语句,只引用公式的第一条输出结果,Expr可使用主指标中的参数,不可使用主指标的变量;当Code=''时引用当前品种,Period=0时引用当前周期类型。  STKCALC('',6,'MA(C,5)')。表示引用当前品种日线周期的5日均线结果。
STKCALC(OPTIONINFO(01),6,'VOLATILITY(N)')。表示引用期权标的日线的N日历史波动率。
 
函数 功能 解释 示例
数据引用
STKDATA(Code,Period,'DATA')
跨品种、周期引用DATA行情数据 DATA限历史行情和数据时间数据。
Code为品种代码,当代码为常量时,可以动态更新该品种数据,否则只能使用本地最近保存的数据。Period为周期类型,取值参考DATAPERIOD;DATA为历史行情数据名。
当Code=''时引用当前品种,Period=0时引用当前周期类型。 STKDATA('',1,'CLOSE')。表示引用当前品种的1分钟线历史收盘价。
STKDATA('600000.SH',0,'CLOSE')。表示引用当前周期类型的浦发银行的历史收盘价。
STKINDI(Code,Period,'IDX.LINE',P1,P2,…) 引用指标输出结果 引用指定品种的IDX指标的LINE输出结果。 Code为品种代码,当代码为常量时,可以动态更新该品种数据,否则只能使用本地最近保存的数据。Period为周期类型,取值参考DATAPERIOD;IDX为指标名称,LINE为指定输出,可以省略,默认引用第一条输出;P1之后为指标参数,最多16个,可以省略,默认使用指标公式对应周期的参数。
当Code=''时引用当前品种,Period=0时引用当前周期类型。  
STKINDI('',0,'MACD')。表示引用当前品种当前周期MACD指标的DIF输出。
STKINDI('600000.SH',6,'MA.MA1',5,20,40)。表示引用浦发银行的日线MA指标的MA1输出,指标前三个参数分别为5、20、40,其余参数使用系统设置值。
TFILTER(买,卖,TYPE) 交易信号过滤 过滤连续出现的交易信号信号。过滤掉买(卖)信号发出后、下一个卖(买)信号发出前的所有买(卖)信号。
TYPE=1表示仅对买信号过滤;TYPE=2表示仅对卖信号过滤;TYPE=0表示对买卖信号都过滤。
ENTERLONG:TFILTER(买,卖,1);
EXITLONG:TFILTER(买,卖,2);
 
函数 功能 解释 示例
数据统计
BARSCOUNT(X) 首个有效值周期数 X的第一个有效数据到当前周期的周期数。 BARSCOUNT(CLOSE)。
对于日线数据取得上市以来总交易日数,对于分笔成交取得当日成交笔数。
BARSLAST(X) 前次条件成立周期数 上一次满足X条件到当前周期的周期数。 BARSLAST(CLOSE/REF(CLOSE,1)>=1.09)。
表示上一个涨停板到当前的周期数。
BARSSINCE(X) 首次条件成立周期数 第一次满足X条件到当前周期的周期数。 BARSSINCE(HIGH>20)。表示股价超过20元时到当前的周期数。
函数 功能 解释 示例
数据统计
COUNT(X,N) 满足条件周期数 统计最近N周期内满足X条件的周期数,N=0时表示从X的第一个有效值开始统计。 COUNT(CLOSE<OPEN,10),表示统计最近10周期内收阴的周期数。
COUNT2(X,A) 统计周期数 统计最近A周期内满足X条件的周期数,A可以为序列数。 COUNT2(CLOSE>OPEN,HHVBARS(HIGH,0)),表示统计上一个新高到当前周期内上涨的周期数。
DMA(X,A) 动态移动平均 以A为平滑因子的X的动态移动平均值。
算法:若Y=DMA(X,A),则Y=A*X+(1-A)*Y',其中Y'表示上一周期Y值,A必须大于0且小于1。 DMA(CLOSE,VOL/CAPITAL),表示以换手率作平滑因子的动态收盘均价。
EMA(X,N) 指数平滑移动平均 X的N周期指数平滑移动平均值。
算法:若Y=EMA(X,N),则Y=[2*X+(N-1)*Y']/(N+1),其中Y'表示上一周期Y值。
EMA(CLOSE,20),表示20周期指数平滑收盘均价。
EMA2(X,N) 加权移动平均 X的N周期加权移动平均值,同WMA。
算法:若Y=EMA2(X,A),则Y=(1*X1+2*X2+…+N*XN)/(1+2+…+N),X1表示N-1周期前的X值,XN表示当前周期的X值,其余类推。
EMA2(CLOSE,20),表示20周期的加权收盘均价。
HHV(X,N) 近期最高值 最近N周期内X的最高值,N=0时表示从X的第一个有效值开始统计。 HHV(HIGH,30),表示最近30周期的最高价。
HHVBRAS(X,N) 近期高点位置(周期数) 最近N周期内X的最高值到当前周期的周期数,N=0时表示从X的第一个有效值开始统计。 HHVBARS(HIGH,0),表示求历史新高到到当前的周期数。
IMPLIEDVOLATILITY(N,r,X)
期权隐含波动率 该函数对期权品种有效。统计当前期权合约隐含波动率。N为标的商品历史波动率的采样周期数;r为市场无风险利率,通常由RISKFREERATE函数获得;X为外部计算的标的历史波动率,该参数可忽略,若填了该参数则忽略N。 IMPLIEDVOLATILITY(50,RISKFREERATE)。表示根据期权标的商品的50周期历史波动率及系统设置的市场无风险利率统计出期权合约的隐含波动率。
IMPLIEDVOLATILITY(0,RISKFREERATE,STKCALC(OPTIONINFO(01),6,'VOLATILITY(60)')),表示以标的60日历史波动率计算期权的隐含波动率。
LLV(X,N) 近期最低值 最近N周期内X的最低值,N=0时表示从X的第一个有效值开始统计。 LLV(LOW,0),表示求历史最低价。
LLVBRAS(X,N) 近期最低点位置(周期数) 最近N周期内X的最低值到当前周期的周期数,N=0时表示从X的第一个有效值开始统计。 LLVBARS(LOW,10),表示最近10周期内出现最低价到当前的周期数。
MA(X,N) 简单移动平均 X的N周期简单移动平均值。
算法:(X1+X2+…+XN)/N,X1表示N-1周期前的X值,XN表示当前周期的X值,其余类推。 MA(CLOSE,10),表示10周期收盘均价。
MEMA(X,N) 改良指数平滑移动平均 X的N周期改良指数平滑移动平均值。
算法:若Y=MEMA(X,N),则Y=[X+(N-1)*Y']/N,其中Y'表示上一周期Y值。 MEMA(CLOSE,30),表示30周期改良指数平滑收盘均价。
OPTIONGREEKVALUE(N,r,K,X) 期权合约特征值 该函数对期权品种有效。
统计当前期权合约的特征值(Delta,Gamma,Theta,Vega,Rho)。N为标的商品历史波动率的采样周期数;r为市场无风险利率,通常由RISKFREERATE函数获得;K为特征值类型:
1-Delta,2-Gamma,3-Theta,4-Vega,5-Rho;
X为外部计算的标的历史波动率,该参数可忽略,若填了该参数则忽略N。 OPTIONGREEKVALUE(50,RISKFREERATE,1),表示根据期权标的商品的50周期历史波动率及系统设置的市场无风险利率统计出期权合约的Delta值。
OPTIONGREEKVALUE(0,RISKFREERATE,1,STKCALC(OPTIONINFO(01),6,'VOLATILITY(60)')),表示以标的60日历史波动率计算期权的Delta值。
SMA(X,N,M) 平滑移动平均 以M为平滑系数的X的N周期移动平均值。
算法:若Y=SMA(X,N,M),则Y=[M*X+(N-M)*Y']/N,其中Y'表示上一周期Y值,M必须大于0且小于N。 SMA(CLOSE,20,1),表示以1为平滑系数的20周期移动收盘均价。
SUM(X,N) 统计近期总和 统计最近N周期的X值总和,N=0时表示从X的第一个有效值开始统计。 SUM(VOL,0),表示统计从第一根K线以来的成交量总和。
VOLATILITY(N,Code) 历史波动率 取N个周期样本统计Code品种的价格历史波动率。Code可以忽略,则函数形式为VOLATILITY(N),表示统计当前商品的历史波动率。 VOLATILITY(50,'000001.SH'),表示上证指数50周期历史波动率。
WMA(X,N)
加权移动平均 X的N周期加权移动平均值。
算法:若Y=WMA(X,A),则Y=(1*X1+2*X2+…+N*XN)/(1+2+…+N),X1表示N-1周期前的X值,XN表示当前周期的X值,其余类推。
例如:
WMA(CLOSE,20),表示20周期的加权收盘均价。
 
 
函数 功能 解释 示例
日历时间
CURRENTDATE 本地当前日期 取1900年为起点表示的本地当前日期,格式:YYYYMMDD。 格式示例:20171027。
表示2017年10月27日
CURRENTTIME 本地当前时间 取本地当前时间
格式HHMMSS。 格式示例:231015
表示23时10分15秒
CURRENTWEEKDAY 本地当前星期数 取本地当前时间的星期数,返回范围为0-6,0表示周日。
DAYOFDATE(DATE1) 指定日期的日 取日期的日(公历几号)。
DATE1为以1900年为起点表示的日期常数或常变量,格式YYYYMMDD。 DAYOFDATE(20171027)
返回值为27
同日用DAYOFDATE(DATE)
返回值为27
HOUROFTIME(X) 指定时间的小时 取时间X的小时。
X为时间常数或常变量,格式HHMMSS。
MINUTEOFTIME(X) 指定时间的分钟 取时间X的分钟。
X为时间常数或常变量,格式HHMMSS。
MONTHOFDATE(X) 指定日期的月份 取日期X的月份。
X为以1900年为起点表示的日期常数或常变量,格式YYYMMDD。
SECONDOFTIME(X) 指定时间的秒 取时间X的秒钟
X为时间常数或常变量,格式HHMMSS。
YEAROFDATE(X) 指定日期的年份 取日期X的年份。
X为以1900年为起点表示的日期常数或常变量,格式YYYMMDD,函数返回实际年份。
 
 
函数 功能 解释 示例
数据时间
BARPOS 数据位置 取当前周期数据在所有数据中的位置。
对于完整的日线数据,该函数表示上市日到该周期的总交易天数。
BARSTATUS 数据位置状态 取当前周期数据所在位置的状态,1表示第一个数据,2表示最后一个数据,0表示中间位置。
DATE 数据日期 取当前周期数据以1900年为起点表示的日期,格式YYYMMDD。
DATEDIFF(DATE1,DATE2) 间隔天数 返回DATE1、DATE2两个日期之间相差的实际天数。DATE1、DATE2为以1900年为起点表示的日期序列变量或常数,格式YYYMMDD,DATE2晚于DATE1。 DATEDIFF(REF(DATE,1)
DATE),表示计算当前周期距离上一周期的天数。
DAY 数据日 取当前周期数据日期的日。
HOUR 数据小时 取当前周期数据时间的小时数。 注意:该函数适用于日线以下分析周期。
ISLASTBAR 最后一个周期 当前周期是否最后一个周期。
ISLASTPERIOD 最后一个周期 当前周期是否最后一个周期, 同ISLASTBAR。
LDAY 数据农历日 取当前周期数据日期所在的农历日。
LMONTH 数据农历月份 取当前周期数据日期所在的农历月份,其中闰月与平月记为同一月。
LYEAR 数据农历年份 取当前周期数据日期所在的农历年份。
MINUTE 数据分钟 取当前周期数据时间的分钟数。
注意:该函数适用于日线以下分析周期。
MONTH 数据月份 取当前周期数据日期的月份。
NEXTDATE(N) N天之后的日期 取当前周期对应的N天之后的日期, 日期格式与DATE相同。
NEXTWEEK(N) N周之后的日期 取当前周期对应的N周之后的日期。 日期格式与DATE相同。
PREVDATE(N) N天之前的日期 取当前周期对应的N天之前的日期。 日期格式与DATE相同。
PREVWEEK(N) N周之前的日期 取当前周期对应的N周之前的日期。 日期格式与DATE相同。
T0TOTIME(X) 秒数转换时间 将距离0点的秒数X转换成时间数据。
X为序列变量或常数,函数返回时间格式HHMMSS。
TIME 数据时间 取当前周期数据的时间,格式HHMMSS。
注意:该函数适用于日线以下分析周期。
TIME0 零点钟以来的秒数 取当前周期数据时间距离当日0点的秒数。
注意:该函数适用于日线以下分析周期。
TIMETOT0(X) 时间转换秒数 将时间X转换成距离0点的秒数。
X为时间序列变量或常数,格式HHMMSS。
WEEKDAY 数据星期数 取当前周期数据日期的星期数。
YEAR
数据年份 取当前周期数据日期的实际年份。
 
 
 
函数 功能 解释 示例
交易所时间
CLOSETIME 交易所收盘时间 取交易所的收盘时间,以0点以来分钟数表示。
MARKETDATE 交易所日期 取交易所最后一笔交易的日期,日期格式与DATE相同。 注意:该函数需系统联机有效。
MARKETSTATUS 交易所状态 取交易所当前交易状态,0-休市,2-开市。 注意:该函数需系统联机有效。
MARKETTIME 交易所时间 取交易所最后一笔交易的时间,时间格式与TIME相同。 注意:该函数需系统联机有效。
OPENTIME 交易所开盘时间 取交易所的开盘时间,以0点以来分钟数表示。
TIMEPOINT
交易所分钟数 取交易所最后一笔交易的时间对应的当日交易分钟数。 注意:该函数需系统联机有效。
TOTALPOINT 交易所总分钟数 取交易所每日总交易分钟数。
 
函数 功能 解释 示例
数学运算
ABS(X) 求绝对值 求X的绝对值。
ACOS(X) 反余弦 求X的反余弦值。
ASIN(X) 反正弦 求X的反正弦值。
ATAN(X) 反正切 求X的反正切值。
CEILING(X) 向上舍入 返回沿X数值增大方向最接近的整数。 CEILING(12.3)返回13
CEILING(-3.5)返回-3。
COS(X) 余弦 求X的值。
EXP(X) 指数 求e的X次幂。
FLOOR(X) 向下舍入 返回沿X数值减小方向最接近的整数。 FLOOR(12.3)返回12
FLOOR(-3.5)返回-4。
FRACPART(X) 数的小数部分 求数值X的小数部分。 FRACPART(1.2)返回0.2
FRACPART(-2.34)返回-0.34。
INTPART(X) 数的正数部分 求数值X的整数部分。 INTPART(2.3)返回2
INTPART(-1.2)返回-1。
LN(X) 自然对数 求以e为底的X的对数。
LOG(X) 常用对数 求以10为底的X的对数。
MAX(A,B,…) 取最大值 求所有参数中的最大值
该函数最多允许16个参数。 MAX(3,5,9,1,2,5)
返回值为9
MIN(A,B,…) 取最小值 求所有参数中的最小值
该函数最多允许16个参数。 MIN(3,5,9,6,4,1,7,8)
返回值为1
MOD(X,N) 求余数 求X关于N的模(X除以N的余数)。 MOD(5,3)返回2,MOD(-5,3)返回-2。
POW(X,N) 乘幂 求X的N次幂,即N个X相乘。
RAND(N) 生成随机数 生成一个范围在[1, N]之间的随机整数。 RAND(10)-1,将随机产生一个0-9之间的整数。
REVERSE(X) 相反数 求X的相反数,同-X。 REVERSE(-3),返回3
ROUND(X) 四舍五入 返回X四舍五入后的整数。
SGN(X)
判断正负 求X数值的符号值,返回1表示正数,-1表示负数,0表示X为0。 SGN(-2398)
返回值为-1
SIN(X) 正弦 求X的正弦值。
SQRT(X) 开平方 求X的平方根,X必须为非负数。
TAN(X) 正切 求X的正切值。
 
函数 功能 解释 示例
逻辑函数
&& A && B,用法:同AND。
ALL(COND,N) 一直满足 最近N周期内是否一直满足COND条件。 ALL(CLOSE>OPEN,10),表示最近10周期是否一直是阳线。
AND A AND B
条件A与条件B同时成立时结果为真,否则为假。
ANY(COND,N)
存在 最近N周期内是否存在COND条件成立。 ANY(CLOSE>OPEN,10),表示最近10周期是否出现过阳线。
BETWEEN(X,A,B) 介于 X处于A、B之间时结果为真,否则为假。 BETWEEN(CLOSE,MA(CLOSE,10),MA(CLOSE,5)),表示收盘价介于5日均线和10日均线之间。
CROSS(A,B)
向上穿越 当A从下方向上穿过B时结果为真,否则为假。 CROSS(MA(CLOSE,5),MA(CLOSE,10))
表示5日收盘均线上穿10日收盘均线。
IF(COND,A,B)
是非判断 (如果、否则条件选择)如果COND条件成立,函数返回A,否则返回B。 IF(CLOSE>OPEN,HIGH,LOW),表示该周期收阳则取最高价,否则取最低价。
IFS(COND,STR1,STR2) 条件选择字符串 如果COND条件成立,函数返回字符串STR1,否则返回字符串STR2。 IFS(CLOSE>=OPEN,'涨','跌'),表示该周期收阳或平盘则取'涨',否则取'跌'。
LAST(COND) 持续周期数 统计最近持续满足COND条件的周期数。 LAST(CLOSE>OPEN),表示最近连续收阳的周期数。
LASTCROSS(A,B,N) 上穿维持周期 N周期前A上穿B,并且此后N周期内保持A大于B。N=0时,与CROSS(A,B)相同。 LASTCROSS(MA(C,10),MA(C,5),5),表示10周期收盘均线上穿5周期收盘均线后,继续维持了5个周期。
LONGCROSS(A,B,N) 持续后上穿 最近N周期内A都小于B,并且当前周期A从下方向上穿过B时结果为真,否则为假。 LONGCROSS(MA(CLOSE,5),MA(CLOSE,10),5),表示5日收盘均线持续5天低于10日收盘均线后上穿10日均线。
SLOWDOWNCROSS(A,B,N) 维持后下穿 最近N周期内维持A大于B,并在当前周期出现A下穿B,则返回1,否则返回0。 SLOWDOWNCROSS(MA(CLOSE,5),MA(CLOSE,10),5)。表示5日收盘均线持续5天维持5日后下上穿10日收盘均线。
SLOWUPCROSS(A,B,N) 维持后上穿 同逻辑函数LONGCROSS(A,B,N)。
NOT(COND) 非(否定) 取COND相反的条件,当COND成立时结果为假,反之为真。 NOT(ISUP),表示平盘或下跌。
OR 或运算符 A  or  B。 条件A与条件B只要有一个成立时结果即为真,二者都不成立时才为假。
RANGE(X,A,B) 介于某范围 X大于A且X小于B时结果为真,否则为假,同X>A AND X<B。 RANGE(CLOSE,MA(CLOSE,10),MA(CLOSE,5)),表示收盘价高于10日均价并低于5日均价。
VALUEWHEN(COND,X) 条件跟随 当COND条件成立时,函数返回X值,否则取VALUEWHEN的前周期返回值。
A XOR B 异或 条件A与条件B有且仅有一个成立时结果为真,否则为假。 NOT(ISUP XOR ISDOWN),相当于ISEQUAL。
|| A || B  。用法同OR。
 
函数 功能 解释 示例
计量统计
AVEDEV(X,N) 平均绝对偏差 求N周期采样的X的平均绝对偏差。
BETA(N) 贝塔系数 求当前股票收益与大盘收益的N周期采样贝塔系数。假设系数值为V,则表明大盘每变动1%,该品种价格可能将变动V%。
BETAEX(X,Y,N)
相关放大系数 求N周期采样的X与Y的相关放大系数。
假设系数值为V,则表明Y每变动1%,X可能将变动V%。 BETAEX(C/REF(C,1)-1,INDEXC/REF(INDEXC,1)-1,5)。表示个股收益与大盘收益的相关放大系数,即贝塔系数,与BETA(5)结果相同。
COVAR(X,Y,N) 协方差 求N周期采样的X与Y的协方差。
DEVSQ(X,N) 偏差平方和 求N周期采样的X的数据偏差平方和。
FORCAST(X,N) 线性回归 求N周期采样的X的线性回归预测值。
RELATE(X,Y,N) 相关 求N周期采样的X与Y的相关系数。
SLOPE(X,N) 线性回归斜率 求N周期采样的X的线性回归斜率。
STD(X,N) 估算标准差 求N周期采样的X的估算标准差。
STDDEV(X,N) 标准偏差 求N周期采样的X的标准偏差。
STDP(X,N) 总体标准差 求N周期采样的X的总体标准差。
VAR(X,N) 估算样本方差 求N周期采样的X的估算样本方差。
VARP(X,N) 总体样本方差 求N周期采样的X的总体样本方差。
 
 
 
 
 
 
 
 
 
 
 
 
函数 功能 解释 示例
指标公式
COST(N) 成本分布 求当前周期N%获利盘的的价格。 COST(20),表示求20%的获利盘价格,即有20%的持仓在该价格以下,其余80%在该价格以上,为套牢盘。
PEAK(K,N,M,ABS) 之字转向波峰值 之字转向ZIG(K,N,ABS)的前M个波峰的数值,M必须大等于1。 PEAK(1,5,1),表示%5最高价ZIG转向的上一个波峰的数值。
PEAKBARS(K,N,M,ABS) 之字转向波峰位置 之字转向ZIG(K,N,ABS)的前M个波峰到当前周期的周期数,M必须大等于1。 PEAKBARS(0,5,1),表示%5开盘价ZIG转向的上一个波峰到当前的周期数。
SAR(N,S,M) 抛物转向 抛物转向,或称停损点转向。N为计算周期,S为步长,M为极值。 SAR(5,2,10),表示计算5日抛物转向,步长为2%,极限值为10%。
SARTURN(N,S,M) 抛物转向点 抛物转向SAR(N,S,M)的转向点,若发生向上转向则取1,若发生向下转向则取-1,否则取0。 例如:
SARTURN(5,2,10),表示计算5日抛物转向的转向点,步长为2%,极限值为10%。
SAR_POBO(N,S,M) 传统抛物转向 抛物转向(澎博传统算法)。
N为计算周期,S为步长,M为极值。 例如:
SAR_POBO(10,2,20)表示10日抛物转向,步长为2%,极限值为20%。
SLOWDOWNCROSS(A,B,N) 维持后下穿 最近N周期内维持A大于B,并在当前周期出现A下穿B,则返回1,否则返回0。 例如:
SLOWDOWNCROSS(MA(CLOSE,5),MA(CLOSE,10),5),
表示5日收盘均线持续5天维持5日后下上穿10日收盘均线。
SLOWUPCROSS(A,B,N) 维持后上穿 同逻辑函数LONGCROSS(A,B,N)。
TROUGH(K,N,M,ABS) 之字转向波谷值 之字转向ZIG(K,N,ABS)的前M个波谷的数值,M必须大等于1。 TROUGH(1,5,1),表示%5最高价ZIG转向的上一个波谷的数值。
TROUGHBARS(K,N,M,ABS) 之字转向波谷位置 之字转向ZIG(K,N,ABS)的前M个波谷到当前周期的周期数,M必须大等于1。 TROUGHBARS(0,5,1),表示%5开盘价ZIG转向的上一个波谷到当前的周期数。
WINNER(X) 获利盘比例 求当前周期在X价位的获利盘比例。 WINNER(CLOSE),表示成本价在当前收盘价以下的持仓比例,即以收盘价卖出的获利盘比例。
ZIG(K,N,ABS) 之字转向 当价格变化量相对(绝对)超过N%(N)时发生转向。K为常数,表示关注的价格(0:开盘价;1:最高价;2:最低价;3:收盘价;4:低点采用最低价,高点采用最高价)。ABS为0或省略时,表示相对ZIG转向,否则为绝对ZIG转向。 ZIG(3,5),表示收盘价的5%ZIG转向。
函数 功能 解释 示例
绘图函数
DRAWBARLINE(H1,O1,L1,C1) 绘制BAR线 分别以H1、O1、L1、C1为最高价、开盘价、最低价、收盘价,绘制BAR线。 DRAWBARLINE(H,O,L,C),即以当前周期实际最高价、开盘价、最低价、收盘价绘制BAR线。
DRAWBKBMP(COND,BMPFILE) 设置背景图片 当最后一个周期的COND条件成立时,使用BMPFILE指定的图片文件做指标线区域背景,否则使用默认背景。BMPFILE为字符串常量,指定BMP格式文件名,文件必须存放于本系统Bmp目录下。 DRAWBKBMP(C>O,'background'),表示当最末一个数据的收盘价大于开盘价时,使用Bmp\background.bmp图片做指标线区域背景。
DRAWBMP(COND,PRICE,BMPFILE,OFFSET) 绘制位图 当COND条件成立时,在PRICE坐标位置绘制BMPFILE指定的位图,OFFSET可选,表示垂直位置偏移像素。BMPFILE为字符串常量,指定BMP格式文件名,文件必须存放于本系统Bmp目录下。 DRAWBMP(C>O,C,'smile'),表示价格上涨时在收盘价位置绘制Bmp\smile.bmp位图。
DRAWGBK(COND,COLOR1,COLOR2,DIR) 填充背景 当最后一个周期的COND条件成立时,沿DIR指定方向使用COLOR1到COLOR2的渐变色填充指标线区域背景。COLOR1和COLOR2是由颜色函数指定的颜色,DIR为渐变方向:0-水平渐变,1-垂直渐变,省略则为0。COLOR2和DIR可省略,则使用COLOR1填充整个背景。 DRAWGBK(C>O, COLORRGB(255,0,0), COLORRGB(255,255,0),1),
表示当最末一个数据的收盘价大于开盘价时,从左到右从红色到黄色渐变填充指标线区域。
DRAWICON(COND,PRICE,TYPE,OFFSET) 绘制图标 当COND条件成立时,在PRICE坐标位置绘制TYPE对应的系统图标,OFFSET可选,表示垂直位置偏移像素。TYPE为0-8的常数,描述系统图标的序号。 DRAWICON(C>O,C,1),表示价格上涨时在收盘价位置绘制系统第2号图标。
DRAWKLINE(H1,O1,L1,C1) 绘制K线 分别以H1、O1、L1、C1为最高价、开盘价、最低价、收盘价,绘制K线。 DRAWKLINE(H,O,L,C),即以该当前周期实际最高价、开盘价、最低价、收盘价绘制K线。
DRAWKLINEEX(COND,H1,O1,L1,C1) 按条件绘制K线 当COND条件成立时,分别以H1、O1、L1、C1为最高价、开盘价、最低价、收盘价,绘制K线,否则不绘制。 DRAWKLINEEX(C>O,H,O,L,C),表示只有当该周期价格上涨时,才绘制K线。
 
 
 
 
 
 
DRAWLINE(COND1,PRICE1,COND2,PRICE2,EXPAND) 绘制直线段 当COND1条件成立时,取该周期PRICE1位置为线段起点,直至COND2条件成立时取该周期PRICE2位置为线段终点,在两点之间绘制线段,并根据EXPAND制定类型进行线段延长。
EXPAND可选,描述线段延长类型:1-向右延长、2-向左延长、3-双向延长。 DRAWLINE(CROSS(MA(C,5),MA(C,10)),C,CROSS(MA(C,10),MA(C,5)),C,1),
表示以5日均线上穿10日均线为起点,下穿为终点,在收盘价位置绘制直线段,并向右延长。
DRAWNUMBER(COND,PRICE,VALUE,PRECISION) 输出数值 当COND条件成立时,在PIRCE坐标位置输出数值VALUE,PRECISION为常数,指定输出的小数位数。 DRAWNUMBER(C>O,C,C,2),表示价格上涨时在收盘价位置输出收盘价格,输出精度为2位小数。
DRAWRGNGBK(COND,COLOR1,COLOR2) 绘制区域背景色 DRAWRGNGBK(COND,COLOR1,COLOR2)
根据条件绘制当前周期背景色。当COND成立时,当前周期背景色为COLOR1,否则背景色为COLOR2。
COLOR1和COLOR2是由颜色函数指定的颜色, DRAWRGNGBK(MA(C,5)>MA(C,10),COLORRED,COLORGREEN),
表示当5日收盘线高于10日收盘线时,K线图在该周期画红色背景,否则画绿色背景。
DRAWSL(COND,PRICE,SLOPE,LEN,DIR) 绘制斜线 当COND条件成立时,以PRICE坐标位置为起点,价差SLOPE为斜率,根据DIR指定的方向绘制LEN周期长的斜线段。LEN与DIR为常变量或常数,DIR表示绘制方向:1-向左绘制、2-双向绘制、其余-向右绘制。 DRAWSL(CROSS(MA(C,5),MA(C,10)),MA(C,5),C-REF(C,1),5,0),
表示当5日收盘均线上穿10日收盘均线时,以5日均价为起点,当日涨跌为斜率,向右绘制长度为5天的斜线。
DRAWTEXT(COND,PRICE,TEXT,OFFSET) 输出文本字符 当COND条件成立时,在PRICE坐标位置显示TEXT文字,OFFSET可选,表示垂直位置偏移像素。
TEXT可为字符串常量、常变量或序列变量。 DRAWTEXT(CROSS(MA(C,5),MA(C,10)),C,'上穿'),
表示当5日收盘均线上穿10日收盘均线时,在收盘价位置显示文本“上穿”。
FILLRGN(CON,P1,P2) 填充区域 当CON不为0时,填充P1、P2之间的区域。CON、P1、P2可为变量或常数。 FILLRGN(C>REF(C,1),L,H),COLORRED。
FILLRGN2(PRICE1,PRICE2,COND1,COLOR1,COND2,COLOR2,…) 填充区域 根据条件用指定的颜色填充PRICE1和PRICE2坐标之间的区域。
当COND1成立时,用COLOR1填充,否则COND2成立时,用COLOR2填充,依此类推,最多可有10组条件,COLOR1之后的参数可以省略,所有条件都不成立则不填充。
MA1:=MA(C,5);
MA2:=MA(C,10);
FILLRGN2(MA1,MA2,MA1>MA2,COLORRED,MA1<MA2,COLORGREEN);
表示当5日均线大于10日均线时,用红色填充二者之间的区,否则用绿色填充。
PARTLINE(CON,P) 条件画线 当CON不为0时,在P处画线。
CON、P可为变量或常数。 PARTLINE(C>REF(C,1),C),COLORRED。
PARTLINE2(PRICE,COND1,COLOR1,COND2,COLOR2,…) 条件画线 根据条件用指定的颜色画PRICE线。
当COND1成立时,用COLOR1颜色绘制,否则COND2成立时,用COLOR2颜色,依此类推,最多可有10组条件,COLOR1之后的参数可以省略,所有条件都不成立时不绘制。 PARTLINE2(C,C>O,COLORRED,C<O,COLORGREEN),
表示用线段连接相邻周期的收盘价,该周期为阳线时使用红色绘制,为阴线时使用绿色绘制,否则不绘制。
POLYLINE(COND,PRICE) 绘制折线 当COND条件成立时,绘制相邻周期的PRICE线,否则不绘制。 POLYLINE(MA(C,5)>MA(C,10),C)
表示只绘制满足5日均线大于10日均线条件的收盘价线。
STICKLINE(COND,PRICE1,PRICE2,WIDTH,ATTR) 绘制柱线 当COND条件成立时,在PRICE1和PRICE2坐标之间绘制柱状线,柱状宽度为(WIDTH/10)倍的标准K线宽度。
ATTR为柱状属性:个位不为0表示画空心柱,十位以上部分表示水平偏移,范围-1000到1000,表示偏移千分比。 STICKLINE(C>O,C,O,2,501),表示当价格上涨时在收盘价和开盘价之间绘制宽度为0.2倍K线宽度的空心柱状线,向右移动K线宽度的50%。
TEXTOUT(COND,TEXT,ALIGN) 显示提示文本 当最后一个周期的COND条件成立时,以ALIGN指定的对齐方式在指标区域显示TEXT文本提示。
ALIGN为对齐方式:0-居中,1-左居中,2-右居中,3-上居中,4-下居中。ALIGN可以省略,缺省为居中对齐。 TEXTOUT(STKTYPE<>0, '该指标仅适用于国内证券品种', 0)
表示非国内证券品种使用该指标时,居中显示文本提示。
VERTLINE(COND,TYPE) 绘制垂直线 当COND条件成立时,在该周期绘制一根垂直线。TYPE为1-4的常数,表示垂直线类型:1表示虚线'---'、2表示点线'…'、3表示点划线'-.-.-'、4表示双点划线'-..-..-'。 VERTLINE(CROSS(MA(C,5),MA(C,10)),3),表示当5日均线上穿10日均线时,在该周期绘制垂直点划线。
 
 
 
 
 
 
 
 
 
函数 功能 解释 示例
修饰函数
ALIGN(N) 水平对齐 用逗号分隔放在DRAWICON、DRAWBMP、DRAWTEXT、DRAWNUMBER语句之后,设定绘图水平对齐方式。
N为常数,0-左对齐,1-居中,2-右对齐。未指定ALIGN时默认为左对齐。 DRAWTEXT(CROSS(MA(C,5),MA(C,10)),C,'上穿'),ALIGN(0)
表示当5日均线上穿10日均线时,在收盘价位置输出字符串“上穿”,字符串左边缘与当前周期坐标线对齐。
AUTOHIDE 自动隐藏线条 用逗号分隔放在输出语句之后,如果线条输出数据的所有周期均为无效值DRAW_NULL,则隐藏该线条。 MA1:MA(C,60),AUTOHIDE;
CIRCLEDOT 小圆圈 用逗号分隔放在输出语句之后,表示该输出结果以小圆圈形状绘制。 SAR0:SAR(10,2,20),CIRCLEDOT;
表示以小圆圈形式显示抛物转向线SAR(10,2,20)。
COLORSTICK 红绿柱线 用逗号分隔放在输出语句之后,表示该输出结果以红绿柱线显示。 MACD:(DIF-DEA)*2,COLORSTICK;
表示以红绿柱线显示MACD指标线。
CROSSDOT
斜叉线 用逗号分隔放在输出语句之后,表示该输出结果以斜叉线显示。
例如:
MA1:MA(C,5),CROSSDOT;
表示以斜叉线绘制5日均线输出。
FLAGBUY 多头买入标记 用逗号分隔放在输出语句之后,表示该输出为多头买入信号,绘制多头买入图标,与系统关键字ENTERLONG等效。
B1:CROSS(MA(CLOSE,5),MA(CLOSE,20)),FLAGBUY;
表示当5日均线上穿20日均线时,发出多头买入信号,图像上在该周期的最低价位置绘制向上的红色实心箭头。
FLAGBUYSHORT 空头买入标记 用逗号分隔放在输出语句之后,表示该输出为空头买入信号,绘制空头买入图标,与系统关键字ENTERSHORT等效。 B1:CROSS(MA(CLOSE,20),MA(CLOSE,5)),FLAGBUYSHORT;
表示当5日均线下穿20日均线时,发出空头买入信号,图像上在该周期的最低价位置绘制向上的红色空心箭头。
FLAGSELL 多头卖出标记 用逗号分隔放在输出语句之后,表示该输出为多头卖出信号,绘制多头卖出图标,与系统关键字EXITLONG等效。 S1:CROSS(MA(CLOSE,20),MA(CLOSE,5)),FLAGSELL;
表示当5日均线下穿20日均线时,发出多头卖出信号,图像上在该周期的最高价位置绘制向下的绿色实心箭头。
FLAGSELLSHORT 空头卖出标记 用逗号分隔放在输出语句之后,表示该输出为空头卖出信号,绘制空头卖出图标,与系统关键字EXITSHORT等效。 S1:CROSS(MA(CLOSE,5),MA(CLOSE,20)),FLAGSELLSHORT;
表示当5日均线上穿20日均线时,发出空头卖出信号,图像上在该周期的最高价位置绘制向下的绿色空心箭头。
FONTSIZE(N) 字体大小 也可省略括号,FONTSIZEN
用逗号隔开放置在DRAWTEXT、DRAWNUMBER语句之后,指定字体大小。X取值范围为8至72。 DRAWTEXT(CROSS(MA(C,5),MA(C,10)),C,'上穿'),FONTSIZE10;
表示用大小为10的字体输出字符串。
LINETHICK(N) 线宽度(粗细) 用逗号分隔放在输出语句之后,设置该指标线的绘制宽度。N为0-9的常数,表示线宽,N为0表示隐藏指标线。 MA1:MA(C,5),LINETHICK(3);
表示设置5日均线的线宽为3。
NODRAW 不显示绘图 用逗号分隔放在输出语句之后,表示隐藏该指标线或绘图。 MA1:MA(C,5),NODRAW;
表示指标输出MA1为5周期收盘均线,但是不绘制该指标线。
POINTDOT 小圆点 用逗号分隔放在输出语句之后,表示该输出结果以小圆点显示。 MA1:MA(C,5),POINTDOT;
表示以小圆点绘制5日均线输出。
PRECISION(N) 数值精度 用逗号分隔放在输出语句之后,设置输出结果显示的小数位数。N为0-10的常数,表示小时位数。 MA1:MA(C,5),PRECISION(3);
表示指标输出MA1为5周期收盘均线,显示的数值精度为3位小数。
STICK 柱状线 用逗号分隔放在输出语句之后,表示该输出结果以柱状线显示。 VOLUME:VOL,STICK;表示用单一颜色的柱状线绘制成交量图。
VALIGN(N) 垂直对齐 用逗号分隔放在DRAWICON、DRAWBMP、DRAWTEXT、DRAWNUMBER语句之后,设定绘图垂直对齐方式。
N为常数,0-上对齐,1-居中,2-下对齐。未指定VALIGN时默认为居中。 DRAWICON(CROSS(MA(C,5),MA(C,10)),C,1),VALIGN(0);
表示当5日均线上穿10日均线时,在收盘价位置绘制1号图标,图标上沿与收盘价坐标线对齐。
VOLSTICK
成交量柱线 用逗号分隔放在输出语句之后,表示该输出结果以成交量柱线显示。 VOLUME:VOL,VOLSTICK;
表示用成交量柱线绘制成交量图,该周期下跌为绿色,否则为红色。
 
 
 
 
 
 
 
 
 
 
 
函数 功能 解释 示例
颜色函数
COLORbbggrr 自定义颜色 用逗号分隔放在输出语句之后,设定该输出指标线的绘制颜色;或者作为特定绘图函数的参数,设置其颜色值。rr、gg、bb为十六进制常数表示的红绿蓝颜色分量,范围为00-FF。 COLOR000000表示黑色
COLORFFFFFF表示白色
COLORFF0000表示蓝色。
COLORBLACK 黑色。 系统默认颜色:黑色
COLORBLUE 蓝色 系统默认颜色:蓝色
COLORCYAN 青色 系统默认颜色:青色
COLORGRAY 灰色 系统默认颜色:灰色
COLORGREEN 绿色 系统默认颜色:绿色
COLORMAGENTA 洋红色 系统默认颜色:洋红
COLORORANGE 橙色 系统默认颜色:橙色
COLORPURPLE 紫色 系统默认颜色:紫色
COLORRED 红色 系统默认颜色:红色
COLORWHITE 白色 系统默认颜色:白色
COLORYELLOW 黄色 系统默认颜色:黄色
COLORRGB(R,G,B) 自定义颜色 R、G、B分别表示红、绿、蓝颜色分量,为十进制常变量或常数,范围为0-255。 COLORRGB(0,0,0)黑
COLORRGB(255,255,255)白色
COLORRGB(255,0,0)红色。
SYSCOLOR(00) 背景色 取分析图的背景颜色。
SYSCOLOR(01) 坐标轴框色 取分析图的坐标轴框颜色。
SYSCOLOR(02) 坐标文字色 取分析图的坐标文字颜色。
SYSCOLOR(03) 阳K线色 取分析图的阳K线和上涨字颜色。
SYSCOLOR(04) 阴K线色 取分析图的阴K线颜色。
SYSCOLOR(05) 平盘k线色 取分析图的平盘线颜色。
SYSCOLOR(06) 下跌字色 取分析图的下跌字颜色。
SYSCOLOR(07) 大标题色 取分析图的大标题颜色。
SYSCOLOR(08) 图形文字色 取分析图的图形文字颜色。
SYSCOLOR(09) 画线颜色 取分析图的画线工具的线条颜色。
SYSCOLOR(10) 指标颜色一 取分析图的缺省指标颜色一。
SYSCOLOR(11) 指标颜色二 取分析图的缺省指标颜色二。
SYSCOLOR(12) 指标颜色三 取分析图的缺省指标颜色三。
SYSCOLOR(13) 指标颜色四 取分析图的缺省指标颜色四。
SYSCOLOR(14) 指标颜色五 取分析图的缺省指标颜色五。
SYSCOLOR(15) 指标颜色六 取分析图的缺省指标颜色六。
SYSCOLOR(16) 成交量色 取分析图的成交量颜色。
SYSCOLOR(17) 持仓线色 取分析图的走势图持仓线颜色。
SYSCOLOR(18) 龙虎标题底色 取分析图的主力龙虎标题底色。
SYSCOLOR(19) 龙虎历史背景色 取分析图的主力龙虎与资金监控历史背景色。
SYSCOLOR(20) 选中行带边框色 取报表的选中行带边框的颜色。
SYSCOLOR(21) 选中行底色 取报表的选中行底色。
SYSCOLOR(22) 报表栏色 取报表的列表栏目颜色。
SYSCOLOR(23) 报价上涨色 取报表的报价上涨颜色。
SYSCOLOR(24) 报价下跌色 取报表的报价下跌颜色。
SYSCOLOR(25) 报价平盘色 取报表的报价平盘颜色。
SYSCOLOR(26) 报表的头背景色 取报表的头背景颜色。
SYSCOLOR(27) 代码色 取报表的品种代码颜色。
SYSCOLOR(28) 名称色 取报表的品种名称颜色。
SYSCOLOR(29) 成交量色 取报表的成交量颜色。
SYSCOLOR(30) 量闪烁颜色 取报表的量闪烁颜色。
SYSCOLOR(31) 持仓量颜色 取报表的持仓量颜色。
SYSCOLOR(32) 持仓量闪烁颜色 取报表的持仓量闪烁颜色。
SYSCOLOR(33) 总金额颜色 取报表的总金额颜色。
SYSCOLOR(34) 反显背景色 取报表的反显背景色。
SYSCOLOR(35) 反显内容颜色 取报表的反显后的内容颜色。
SYSCOLOR(36) 反显边框颜色 取报表的反显边框颜色。
SYSCOLOR(37) 上涨闪烁颜色 取报表的上涨闪烁颜色。
SYSCOLOR(38) 下跌闪烁颜色 取报表的下跌闪烁颜色。
SYSCOLOR(39) 平盘闪烁颜色 取报表的平盘闪烁颜色。
SYSCOLOR(40) 字体放大颜色 取报表的字体放大颜色。
SYSCOLOR(41) 字段背景颜色 取报表的字段背景颜色。
SYSCOLOR(42) 奇数行背景颜色 取报表的奇数行背景颜色。
SYSCOLOR(43) 偶数行背景颜色 取报表的偶数行背景颜色。
SYSCOLOR(44) 信息文字颜色 取系统的信息文字颜色。
SYSCOLOR(45) 信息背景色 取系统的信息背景色。
 
函数 功能 解释 示例
字符串函数
LIKE(STR1,STR2) 是否相似 比较字符串STR1和STR2是否相似。STR2通常为含有通配符'?'、'%'的字符串,其中'?'表示匹配一个字符,'%'表示匹配任意个连续字符。 LIKE(GETCODE,'6%'),返回1则表示当前品种是上海A股。
LOWERSTR(STR) 小写 返回字符串STR对应的小写字符串。 LOWERSTR('String'),将返回字符串'string'。
LTRIM(STR) 去除前端空格 返回去除字符串STR前端空格(包括Tab制表符)后的字符串。 LTRIM(' LTrim String '),将返回字符串'LTrim String '。
NUMTOSTR(NUM,M) 转换为字符串 将数值NUM按M个小数位转换为字符串,M为0-10的常数。 NUMTOSTR(12.3,2),将返回字符串'12.30'。
RTRIM(STR) 去末端空格 返回去字符串STR末端空格(包括Tab制表符)后的字符串。 RTRIM(' RTrim String '),将返回字符串' RTrim String'。
 
STRCMP(STR1,STR2) 比较字符串 比较字符串STR1和STR2的大小。STR1>STR2时返回1,STR1<STR2时返回-1,相等则返回0。 STRCMP('JONE','JACK'),返回1。
STRFIND(STR,S1,N) 查找子串 从字符串STR的第N个字符开始查找字符串S1,返回找到的位置,若没有找到则返回0。 STRFIND('ABCDEF','CDE',1),将返回3。
STRLEN(STR) 字符串长度 返回字符串STR的字符个数,其中一个汉字占两个字符。
例如:
STRLEN('上海A股'),将返回字符串'上海A股'的长度7。
STRTONUM(STR) 转换为数值 返回数值形式的字符串STR对应的数值。 STRTONUM('12.3')+10,返回结果为22.3。
TRIM(STR) 去除两端空格 返回去除字符串STR两端空格(包括Tab制表符)后的字符串。 TRIM(' Trim String  '),将返回字符串'Trim String'。
UPPERSTR(STR) 大写 返回字符串STR对应的大写字符串。 UPPERSTR('String'),将返回字符串'STRING'。
 
函数 功能 解释 示例
信息查询
DATAPERIOD 周期类型 取当前计算的周期类型。
1-1分钟线,2-5分钟线,3-15分钟线,4-30分钟线,5-60分钟线,6-日线,7-周线,8-月线,9-年线,10-多日线,11-多分钟线,12-季线,13-3分钟线,14-走势线,15-120分钟线,16-240分钟线。
DAYSTOEXPIRED(Code) 合约到期天数 取期货合约距离最后交易日的天数,包含最后交易日。
Code为商品代码,''表示取当前商品。
EXPIREDATE(Code) 最后交易日 取期货合约的最后交易日,格式yyyymmdd。Code为商品代码,''表示取当前商品。
FINDOPTION(Code,Month,Type,StrikePrice) 查找期权 查找指定标的、月份和方向,且行权价最接近StrikePrice的期权合约代码。
Code为标的商品代码,当Code=''时取当前商品;Month为期权月份,格式为YYMM;
Type为期权方向,0-认购(看涨),1-认沽(看跌);StrikePrice为指定行权价,找到的期权合约行权价与该价格最接近。 FINDOPTION('510050.SH',1408,0,1.545);
返回查找到标的为50ETF、月份为1408、行权价约为1.545的认购期权合约代码。
GETCODE 品种代码 取当前品种的代码。
GETGROUPID 分类代码 取当前品种的分类代码。
GETGROUPNAME 分类名称 取当前品种的分类名称。
 
 
 
 
GETMARKETID 交易所代码 取当前品种的交易所代码。
1-上海证券,2-深圳证券,3-板块指数,4-香港证券,5-上海期货,6-大连期货,7-郑州期货,8-中金所,9-LME,10-IPE,11-CMEM金属,12-CME能源,13-CME农产品,14-CME衍生品,15-指数期货,16-SGX,17-TOCOM,18-MALAYSIA,19-全球外汇,20-国际贵金属,21-亚洲指数,22-欧洲指数,23-美洲指数,24-恒指期货,25-上海黄金。
GETMARKETNAME(ID) 交易所名称 取代码为ID的交易所的名称。ID取值参照GETMARKETID函数。 GETMARKETNAME(GETMARKETID),表示取得当前品种的交易所名称。
GETNAME 品种名称 取当前品种的名称。
GETNAMEBYCODE(CODE) 指定品种名称 取品种代码为CODE的品种名称。 GETNAMEBYCODE('600000.SH'),将返回字符串'浦发银行'。
ISCONTRACT(Code) 是否为指定品种 当前是否为指定的品种。 ISCONTRACT('CU')、ISCONTRACT('CU1009')、ISCONTRACT('600100.SH')。
ISSTOCK(Code) 是否属于指定品种 当前是否为指定的品种,同ISCONTRACT。 ISSTOCK('CU')、ISSTOCK('CU1009')、ISSTOCK('600100.SH')。
PRICEPRECISION(Code) 价格精度 取指定商品的价格精度,即系统设定的商品价格的小数位数。Code为商品代码,''表示取当前商品。
RISKFREERATE 市场无风险利率 取系统设置的市场无风险利率。
STKTYPE 品种类型 取当前品种类型。返回值:0-国内证券、1-国内期货、2-外汇、3-国外指数、4-国外期货、5-电子现货、6-香港证券、7-板块指数。
VOLMULTIPLIER(Code) 合约乘数 取指定商品的合约乘数。Code为商品代码,''表示取当前商品。
 
函数 功能 解释 示例
系统函数
 
 
 
 
 
 
 
 
函数 功能 解释 示例
集合函数
LISTSIZE(List)
集合大小 用于List集合的元素个数。
OPTLIST:=OPTIONLIST('510050.SH',1408,0);
FOR I:=1 TO LISTSIZE(OPTLIST) DO
BEGIN
...
END
表示遍历标的为50ETF、月份为1408的认购期权的所有合约。
OPTIONLIST(Code,Month,Type) 获取期权列表 该函数返回集合数据。
用于获取指定标的、月份和方向的所有期权合约代码列表。Code为标的商品代码,当Code=''时引用当前品种;Month为期权月份,格式为YYMM;Type为期权方向,0-认购(看涨),1-认沽(看跌); OPTIONLIST('510050.SH',1408,0);
返回标的为50ETF、月份为1408的认购期权合约代码集合。
 
 
函数 功能 解释
交易系统
 
插件函数
 
自定义函数
 
暂缺函数
KSTYL(type) K线形态 判断K线是否为某个形态或样式
ISHPOS 是否为均线周期高点 判断当前K线是否为其中一均线周期的最高点位置
ISLPOS 是否为均线周期低点 判断当前K线是否为其中一均线周期的最低点位置
ISBEAR(code) 均线是否空头排列
ISBULL(code) 均线是否多头排列
TRANOSC(code) 定义价格振荡区间
ISLAST(type) 判断前交易一个信号
LASTBARS 前一个信号的位置
GETVOL 返回当前持仓量
GETSBU 返回当前持仓方向
 
 
 
 
 
 
 
程序控制语句、语法与指令关键字
 
关键字 功能 用法解释 示例
"" 跨品种引用数据 "CODE$DATA"
引用代码为CODE的品种的DATA数据,DATA限历史行情和数据时间数据。 "CU1108$CLOSE",引用沪铜8月的收盘价;
"EURUSD$HIGH",引用欧元美元的最高价;
"000001.SH$LOW",引用上证指数的最低价;
"399001.SZ$VOL",引用深证成指的成交量;
"HSI.HK$CLOSE",引用恒生指数的收盘价。
ARRAY 数组序列变量标记 ARRAY PARA
用于自定义函数头部声明,标记参数PARA类型为序列变量,否则为常变量。 FUNCTION MYFUNC(ARRAY DATA, N)
  ...
END_FUNCTION
表示实现自定义函数MYFUNC,函数拥有两个参数DATA和N,其中DATA为序列变量,N为常变量。
BEGIN 复合语句 BEGIN
  STATEMENT1
  STATEMENT2
  …
END
组合多条语句,使这些语句从属共同作用域,多用于IF、FOR、WHILE等控制语句。
子语句STATEMENT1等可以是单行语句,也可以是IF、FOR、WHILE、BEGIN…END等复合语句。 VARIABLE:CNT1:=0,CNT2:=0;
CR:=CROSS(MA(C,5),MA(C,10));
FOR I:=1 TO DATACOUNT DO
BEGIN
  IF C[I]>O[I] THEN
    CNT1:=CNT1+1;
  IF CR[I]>0 THEN
    CNT2:=CNT2+1;
END
对于日线表示分别统计当前品种上市以来的上涨次数和5日均线上穿10日均线的次数。
BREAK 强制结束循环 用于FOR和WHILE语句循环体,可以提前结束循环过程。 VARIABLE:CNT:=0;
FOR I:=DATACOUNT TO 1 DO
  IF C[I]>O[I] THEN
    CNT:=CNT+1;
  ELSE
    BREAK;
表示统计最近连续上涨的次数。
CONTINUE; 跳过本次循环 用于FOR和WHILE语句循环体,表示跳过循环体中该语句之后的过程,直接进入下一次循环过程。 VARIABLE:CNT:=0;
FOR I:=1 TO DATACOUNT DO
BEGIN
  IF C[I]<O[I] THEN
    CONTINUE;
  CNT:=CNT+1;
END
表示统计该品种上市以来上涨或平盘的次数。
DO 无限循环语句 参看FOR和WHILE关键字的用法。
DRAWNULL 无效值 表示无效值,为常量。 M1:=MA(C,5);
则M1[1]=DRAWNULL将返回1,而M1[5]=DRAWNULL将返回0。
IF(CLOSE>REF(CLOSE,1),CLOSE,DRAWNULL);
表示下跌时分析图上不画线。
ELSE 判断分支语句 参看IF关键字用法。
END 复合语句 参看BEGIN关键字用法。
END_FUNCTION 自定义函数 参看FUNCTION关键字用法。
ENTERLONG:COND; 多头买入 用于交易系统,当COND条件成立时,发出多头买入信号。 ENTERLONG:CROSS(MA(CLOSE,5),MA(CLOSE,20));
表示当5日收盘均线上穿20日收盘均线时,向系统发出多头买入信号。
ENTERSHORT:COND; 空头买入 用于交易系统,当COND条件成立时,发出空头买入信号。 ENTERSHORT:CROSS(MA(CLOSE,20),MA(CLOSE,5));
表示当5日收盘均线下穿20日收盘均线时,向系统发出空头买入信号。
EXITLONG:COND;
多头卖出 用于交易系统,当COND条件成立时,发出多头卖出信号。 例如:
EXITLONG:CROSS(MA(CLOSE,20),MA(CLOSE,5));
表示当5日收盘均线下穿20日收盘均线时,向系统发出多头卖出信号。
EXITSHORT:COND; 空头卖出 用于交易系统,当COND条件成立时,发出空头卖出信号。 例如:
ENTERLONG:CROSS(MA(CLOSE,5),MA(CLOSE,20));
表示当5日收盘均线上穿20日收盘均线时,向系统发出空头卖出信号。
 
 
 
 
 
FOR 有限循环 FOR I:=N0 TO N [STEP S] DO
  STATEMENT
表示计数器I以步长S从N0增加或减少至N,循环执行STATEMENT语句。
N0、N、S均为常数或常变量。
“STEP S”可以省略,使用默认步长1(N>N0)或-1(N<N0);若指定S,必须满足N>N0时S为正、N<N0时S为负。
STATEMENT可以为单行语句,也可以是IF、FOR、WHILE、BEGIN…END等复合语句。 VARIABLE:CNT:=0;
FOR I:=1 TO DATACOUNT STEP 1 DO
  IF C[I]>O[I] THEN
    CNT:=CNT+1;
对于日线表示统计当前品种上市以来的上涨次数。
FUNCTION 自定义函数 FUNCTION F([ARRAY] PARA1,[ARRAY] PARA2,...)
  STATEMENT
  [RETURN RET;]
END_FUNCTION
实现自定义函数F,可在之后的脚本语句中调用,避免重复编写相同逻辑。
F为自定义函数名称;PARAN为传入函数的参数名,前面的"ARRAY"可以省略,表示PARAN为常变量,否则通过ARRAY限定PARAN为序列变量;参数PARAN均可以省略,则F是不带参数的函数,引用时可省略括号;"RETURN RET;"指定函数的返回结果,结果类型由RET确定,该语句可以省略,则函数返回无效值。 FUNCTION MPRICE(ARRAY HPRICE, ARRAY LPRICE)
  RETURN (HPRICE+LPRICE)/2;
END_FUNCTION
MIDPRICE:MPRICE(HIGH, LOW)
表示自定义求中间价的函数MPRICE,输出通过该函数计算得到的最高价与最低价的中间价。
GLOBAL 定义全局变量 GLOBAL:X:=1;
定义指标实例的全局变量,与VARIABLE用法相似,但是GLOBAL的变量仅支持常变量,不能初始化为序列变量。全局变量只在实例第一次计算时初始化一次,每次计算后保存最后的变量结果,可供再次计算时使用。 GLOBAL:X:=0;
X:=X+1;
表示在同一个实例中,每次计算后X值都加1,结果就是在实例生存期内,X值反映了公式被调用计算的次数。
 
 
IF 条件判断及分支 IF CONDITION THEN
  STATEMENT
表示当CONDITION条件成立时,才执行STATEMENT语句。
CONDITION必须为常量条件,STATEMENT可以是单行语句,也可以是IF、FOR、WHILE、BEGIN…END等复合语句。 VARIABLE:UP:=0;
IF DYNAINFO(07)>DYNAINFO(04) THEN
  UP:=1;
表示当最新价高于开盘价时,常变量UP值为1,否则为0。
IF CONDITION THEN
  STATEMENT1
ELSE
  STATEMENT2
表示当CONDITION条件成立时,执行STATEMENT1语句,否则执行STATEMENT2语句。
REFLINE 设定参考线 REFLINE:A,B,C,…;
绘制指标线时,在指定的A、B、C等位置设置水平参考线,最多可指定7条参考线,以逗号分隔。 REFLINE:1.5,3,4.5;
表示绘图时指定三条坐标水平参考线:1.5、3、4.5。
RETURN 函数返回 RETURN RET;
通常用于自定义函数体,表示跳过该语句之后的所有过程,结束函数运算。RET可以省略,表示返回无效值,否则函数返回RET结果。
该语句也可用于指标公式主体脚本中,提前结束指标计算,此时RET将被忽略。
有关自定义函数详细信息和示例,参看FUNCTION关键字用法。
STEP 数值序列步长 循环控制语句,参看FOR关键字用法。
 
 
THEN 条件判断 条件判断控制,参看IF关键字用法。 VARIABLE:UP:=0;
IF DYNAINFO(07)>DYNAINFO(04) THEN
BEGIN
   UP:=1;
   ......
END
TO 有限循环结束点 循环控制语句,参看FOR关键字用法 VARIABLE:CNT1:=0,CNT2:=0;
CR:=CROSS(MA(C,5),MA(C,10));
FOR I:=1 TO DATACOUNT DO
BEGIN
  IF C[I]>O[I] THEN
    CNT1:=CNT1+1;
  IF CR[I]>0 THEN
    CNT2:=CNT2+1;
END
对于日线表示分别统计当前品种上市以来的上涨次数和5日均线上穿10日均线的次数。
VARIABLE 声明变量 VARIABLE:A1:=V1,A2:=V2,...;
声明变量A1、A2…,并分别初始化A1=V1、A2=V2…,变量的类型由初始化类型确定,即AN类型与VN相同。 VARIABLE:A:=1,B:=C;
声明定义了常变量A和序列变量B,A的初值为1,B的初值为收盘线。
WHILE 条件循环 WHILE CONDITION DO
  STATEMENT
表示当CONDITION条件成立时,循环执行STATEMENT语句,直至CONDITION不成立结束循环。
CONDITION必须为常量条件,STATEMENT可以是单行语句,也可以是IF、FOR、WHILE、BEGIN…END等复合语句。
(注意:使用此语法时务必确保逻辑在实际情况下的可行性,避免出现死循环,请慎用。) VARIABLE:CNT:=0,I:=1;
WHILE I<DATACOUNT DO
BEGIN
  IF C[I]>O[I] THEN
    CNT:=CNT+1;
  I:=I+1;
END
对于日线表示统计当前品种上市以来的上涨次数。
[] 数组元素索引列表 ARR[N]
引用序列量ARR的第N个值。ARR支持序列变量、历史行情函数和数据时间函数。
CLOSE[DATACOUNT],表示引用最后一个收盘价;DATE[1],表示取第一个历史数据时间,即上市日期;M5:=MA(CLOSE,5),则M5[5]表示取第一个有效的5日收盘均线。
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
 
技术指标公式算法及应用
指标 解释 示例
主图指标
 
 
成交量指标
ADVOL 钱龙离散量 A:=SUM(((CLOSE-LOW)-(HIGH-CLOSE))*VOL/10000/(HIGH-LOW),0);
ADVOL:A;
ADVOLMA:MA(A,30);
AMOUNT 持仓量(成交额) 1.成交金额大,代表交投热络,可界定为热门股;
2.底部起涨点出现大成交金额,代表攻击量;
3.头部地区出现大成交金额,代表出货量;
4.观察成交金额的变化,比观察成交手数更具意义,因为成交手数并未反应股价的涨跌的后所应支出的实际金额。 
M1:=6;//minM1:=0,maxM1:=60
M2:=12;//minM2:=0,maxM2:=120
M3:=24;//minM3:=0,maxM3:=240
AMO:AMOUNT,VOLSTICK;
MAAMO1:MA(AMO,M1);
MAAMO2:MA(AMO,M2);
MAAMO3:MA(AMO,M3);
OI 线性持仓 OI:AMOUNT;
 
VOL 成交量 1.成交量大,代表交投热络,可界定为热门股;
2.底部起涨点出现大成交量(成交手数),代表攻击量;
3.头部地区出现大成交量(成交手数),代表出货量;
4.观察成交金额的变化,比观察成交手数更具意义,因为成交手数并未反应股价的涨跌的后所应支出的实际金额。
M1:=5;//minM1:=1,maxM1:=10
M2:=10;//minM2:=5,maxM2:=30
VOLUME:VOL,VOLSTICK;
MAVOL1:MA(VOLUME,M1);
MAVOL2:MA(VOLUME,M2);
趋向指标
BBI 多空指数 1.股价位于BBI 上方,视为多头市场;
2.股价位于BBI 下方,视为空头市场。
M1:=3; //minM1:=1,maxM1:=100
M2:=6; //minM2:=1,maxM2:=100
M3:=12;//minM3:=1,maxM3:=100
M4:=24;//minM4:=1,maxM4:=100
BBI:(MA(CLOSE,M1)+MA(CLOSE,M2)+MA(CLOSE,M3)+MA(CLOSE,M4))/4;
DDI 方向标准离差指数 N:=13;  //minN:=1,maxN:=100
N1:=30; //minN1:=1,maxN1:=100
M:=10;  //minM:=1,maxM:=100
M1:=5;  //minM1:=1,maxM1:=100
TR:=MAX(ABS(H-REF(H,1)),ABS(L-REF(L,1)));
DMZ:=IF((H+L)<=(REF(H,1)+REF(L,1)),0,MAX(ABS(H-REF(H,1)),ABS(L-REF(L,1))));
DMF:=IF((H+L)>=(REF(H,1)+REF(L,1)),0,MAX(ABS(H-REF(H,1)),ABS(L-REF(L,1))));
DIZ:=SUM(DMZ,N)/(SUM(DMZ,N)+SUM(DMF,N));
DIF:=SUM(DMF,N)/(SUM(DMF,N)+SUM(DMZ,N));
DDI:DIZ-DIF,COLORSTICK;
ADDI:SMA(DDI,N1,M);
AD:MA(ADDI,M1);
DMA 平均线差 1.DMA 向上交叉其平均线时,买进;
2.DMA 向下交叉其平均线时,卖出;
3.DMA 的交叉信号比MACD、TRIX 略快;
4.DMA 与股价产生背离时的交叉信号,可信度较高;
5.DMA、MACD、TRIX 三者构成一组指标群,互相验证。
SHORT:=10;//minSHORT:=2,maxSHORT:=300
LONG:=50;//minLONG:=10,maxLONG:=300
M:=10;//minM:=1,maxM:=300
DDD : (MA(CLOSE,SHORT)-MA(CLOSE,LONG));
AMA : MA(DDD,M);
 
DMI 趋向指标(标准) 1.PDI 向上交叉MDI ,买进;PDI 向下交叉MDI ,卖出;
2.ADX 在高于50的地方向下反折时,应小心股价随时有反转的可能;
3.ADX 小于20时,意味股价将进行盘整,此时不宜买卖及使用技术指标。
N:=14;//minN:=2,maxN=100
M:=6;//minM:=1,maxM:=100
TR := SUM(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(
LOW-REF(CLOSE,1))),N);
HD := HIGH-REF(HIGH,1);
LD := REF(LOW,1)-LOW;
DMP:= SUM(IF(HD>0 AND HD>LD,HD,0),N);
DMM:= SUM(IF(LD>0 AND LD>HD,LD,0),N);
PDI: DMP*100/TR;
MDI: DMM*100/TR;
ADX: MA(ABS(MDI-PDI)/(MDI+PDI)*100,M);
ADXR:(ADX+REF(ADX,M))/2;
DMI-QL 趋向指标(钱龙) N:=14;//minN:=2,maxN:=100
M:=6;//minM:=1,maxM:=100
REFLINE: 0, 20, 50, 80, 100;
TR := SMA(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(
LOW-REF(CLOSE,1))),N,1);
HD := HIGH-REF(HIGH,1);
LD := REF(LOW,1)-LOW;
DMP:= SMA(IF(HD>0 AND HD>LD,HD,0),N,1);
DMM:= SMA(IF(LD>0 AND LD>HD,LD,0),N,1);
PDI: DMP*100/TR;
MDI: DMM*100/TR;
ADX: SMA(ABS(MDI-PDI)/(MDI+PDI)*100,N,1);
ADXR:(ADX+REF(ADX,M))/2;
EXPMA 指数平滑移动平均线 1.EXPMA 一般以观察12日和50日二条均线为主;
2.12日指数平均线向上交叉50日指数平均线时,买进;
3.12日指数平均线向下交叉50日指数平均线时,卖出;
4.EXPMA 是多种平均线计算方法的一;
5.EXPMA 配合MTM 指标使用,效果更佳。
P1:=5;  //minP1:=1,maxP1:=300
P2:=10; //minP2:=1,maxP2:=300
P3:=20; //minP3:=1,maxP3:=300
P4:=60; //minP4:=1,maxP4:=300
MA1:EMA(CLOSE,P1);
MA2:EMA(CLOSE,P2);
MA3:EMA(CLOSE,P3);
MA4:EMA(CLOSE,P4);
HMA 高价平均线 一般移动平均线以收盘价为计算基础,高价平均线是以每日最高价为计算基础。目前市场上许多投资人将其运用在空头市场,认为它的压力效应比传统平均线更具参考价值。
M1:=6;  //minM1:=2,maxM1:=250
M2:=12; //minM2:=2,maxM2:=250
M3:=30; //minM3:=2,maxM3:=250
M4:=72; //minM4:=2,maxM4:=250
M5:=144;//minM5:=2,maxM5:=250
HMA1:MA(HIGH,M1);
HMA2:MA(HIGH,M2);
HMA3:MA(HIGH,M3);
HMA4:MA(HIGH,M4);
HMA5:MA(HIGH,M5);
JLHB 绝路航标 反趋势类选股指标。综合了动量观念、强弱指标与移动平均线的优点,在计算过程中主要研究高低价位与收市价的关系,反映价格走势的强弱和超买超卖现象。在市场短期超买超卖的预测方面又较敏感。
作者:李济安
N:=7;//minN:=2,maxN:=100
M:=5; //minM:=2,maxM:=100
VAR1:=(CLOSE-LLV(LOW,60))/(HHV(HIGH,60)-LLV(LOW,60))*80; 
B:SMA(VAR1,N,1); 
VAR2:SMA(B,M,1); 
绝路航标:IF(CROSS(B,VAR2) AND B<40,50,0);
JS 加速线 加速线指标是衡量股价涨速的工具,加速线指标上升表明股价上升动力增加,加速线指标下降表明股价下降压力增加。加速线适用于DMI表明趋势明显时(DMI.ADX大于20)使用:
1.如果加速线在0值附近形成平台,则表明既不是最好的买入时机也不是最好的卖入时机;
2.在加速线发生金叉后,均线形成底部是买入时机。
3.在加速线发生死叉后,均线形成顶部是卖出时机。
N:=5;   //minN:=2,maxN:=100
M1:=5;  //minM1:=2,maxM1:=100
M2:=10; //minM2:=2,maxM2:=100
M3:=20; //minM3:=2,maxM3:=100
JS:100*(CLOSE-REF(CLOSE,N))/(N*REF(CLOSE,N));
MAJS1:MA(JS,M1);
MAJS2:MA(JS,M2);
MAJS3:MA(JS,M3);
LMA 低价平均线
(主图叠加) 一般移动平均线以收盘价为计算基础,低价平均线是以每日最低价为计算基础。目前市场上许多投资人将其运用在多头市场,认为它的支撑效应比传统平均线更具参考价值。
M1:=6;  //minM1:=2.maxM1:=250
M2:=12; //minM2:=2.maxM2:=250
M3:=30; //minM3:=2.maxM3:=250
M4:=72; //minM4:=2.maxM4:=250
M5:=144;//minM5:=2.maxM5:=250
LMA1:MA(LOW,M1);
LMA2:MA(LOW,M2);
LMA3:MA(LOW,M3);
LMA4:MA(LOW,M4);
LMA5:MA(LOW,M5);
MA 均价
(主图叠加) 1.股价高于平均线,视为强势;股价低于平均线,视为弱势
2.平均线向上涨升,具有助涨力道;平均线向下跌降,具有助跌力道;
3.二条以上平均线向上交叉时,买进;
4.二条以上平均线向下交叉时,卖出;
5.移动平均线的信号经常落后股价,若以EXPMA 、VMA 辅助,可以改善。
P1:=5;  //minP1:=0,maxP1:=1000
P2:=10; //minP2:=0,maxP2:=1000
P3:=15; //minP3:=0,maxP3:=1000
P4:=20; //minP4:=0,maxP4:=1000
P5:=30; //minP5:=0,maxP5:=1000
P6:=40; //minP6:=0,maxP6:=1000
P7:=60; //minP7:=0,maxP7:=1000
P8:=0;//minP8:=0,maxP8:=1000
MA_P1_:MA(CLOSE,P1),AUTOHIDE;
MA_P2_:MA(CLOSE,P2),AUTOHIDE;
MA_P3_:MA(CLOSE,P3),AUTOHIDE;
MA_P4_:MA(CLOSE,P4),AUTOHIDE;
MA_P5_:MA(CLOSE,P5),AUTOHIDE;
MA_P6_:MA(CLOSE,P6),AUTOHIDE;
MA_P7_:MA(CLOSE,P7),AUTOHIDE;
MA_P8_:MA(CLOSE,P8),AUTOHIDE;
MACD 指数平滑异同平均线 1.DIF 向上交叉DEA,买进;DIF 向下交叉DEA,卖出;
2.DIF 连续两次向下交叉DEA,将造成较大的跌幅;
3.DIF 连续两次向上交叉DEA,将造成较大的涨幅;
4.DIF 与股价形成背离时所产生的信号,可信度较高;
5.DMA、MACD、TRIX 三者构成一组指标群,互相验证。
SHORT:=12;//minSHORT:=5,maxSHORT:=40,step:=4
LONG:=26;//minLONG:=20,maxLONG:=100,step:=5
M:=9;//minM=2,maxM:=60,step:=3
DIFF : EMA(CLOSE,SHORT) - EMA(CLOSE,LONG);
DEA  : EMA(DIFF,M);
MACD : 2*(DIFF-DEA), COLORSTICK;
MARSI 相对强弱平均线 1.RSI>20 为超买;RSI<20 为超卖;
2.RSI 以50为中界线,大于50视为多头行情,小于50视为空头行情;
3.RSI 在80以上形成M头或头肩顶形态时,视为向下反转信号;
4.RSI 在20以下形成W底或头肩底形态时,视为向上反转信号;
5.RSI 向上突破其高点连线时,买进;RSI 向下跌破其低点连线时,卖出。
M1:=10;//minM1:=2,maxM1:=100
M2:=6; //minM2:=2,maxM2:=60
DIF:=CLOSE-REF(CLOSE,1);
VU:=IF(DIF>=0,DIF,0);
VD:=IF(DIF<0,-DIF,0);
MAU1:=MEMA(VU,M1);
MAD1:=MEMA(VD,M1);
MAU2:=MEMA(VU,M2);
MAD2:=MEMA(VD,M2);
RSI10:MA(100*MAU1/(MAU1+MAD1),M1);
RSI6:MA(100*MAU2/(MAU2+MAD2),M2);
MASS 梅斯线 1.MASS>27 后,随后又跌破26.5,此时股价若呈上涨状态,则卖出;
2.MASS<27 后,随后又跌破26.5,此时股价若呈下跌状态,则买进;
3.MASS<20 的行情,不宜进行投资。
N1:=9;//minN1:=2,maxN1:=120
N2:=25;//minN2:=2,maxN2:=120
M:=6;//minM:=2,maxM:=120
MASS:SUM(MA(HIGH-LOW,N1)/MA(MA(HIGH-LOW,N1),N1),N2);
MAMASS:MA(MASS,M);
MFI 资金流量指标 1.MFI>80 为超买,当其回头向下跌破80 时,为短线卖出时机;
2.MFI<20 为超卖,当其回头向上突破20 时,为短线买进时机;
3.MFI>80,而产生背离现象时,视为卖出信号;
4.MFI<20,而产生背离现象时,视为买进信号。
N:=14;//minN:=2,maxN:=120
N2:=6;//minN2:=2,maxN2:=60
TYP := (HIGH + LOW + CLOSE)/3;
V1:=SUM(IF(TYP>REF(TYP,1),TYP*VOL,0),N)/SUM(IF(TYP<REF(TYP,1),TYP*VOL,0),N);
MFI:100-(100/(1+V1));
NMA 均价 1.股价高于平均线,视为强势;股价低于平均线,视为弱势
2.平均线向上涨升,具有助涨力道;平均线向下跌降,具有助跌力道;
3.二条以上平均线向上交叉时,买进;
4.二条以上平均线向下交叉时,卖出;
5.移动平均线的信号经常落后股价,若以EXPMA 、VMA 辅助,可以改善。
P1:=3;  //minP1:=0,maxP1:=1000
P2:=5;  //minP2:=0,maxP2:=1000
P3:=10; //minP3:=0,maxP3:=1000
P4:=15; //minP4:=0,maxP4:=1000
P5:=20; //minP5:=0,maxP5:=1000
P6:=30; //minP6:=0,maxP6:=1000
P7:=40; //minP7:=0,maxP7:=1000
P8:=60; //minP8:=0,maxP8:=1000
MA_P1_:MA(CLOSE,P1);
MA_P2_:MA(CLOSE,P2);
MA_P3_:MA(CLOSE,P3);
MA_P4_:MA(CLOSE,P4);
MA_P5_:MA(CLOSE,P5);
MA_P6_:MA(CLOSE,P6);
MA_P7_:MA(CLOSE,P7);
MA_P8_:MA(CLOSE,P8);
PBX 瀑布线 1.股价上升穿越轨道线上限时,回档机率大;
2.股价下跌穿越轨道线下限时,反弹机率大;
3.股价波动于轨道线内时,代表常态行情,此时,超买超卖指标可发挥效用;
4.股价波动于轨道线外时,代表脱轨行情,此时,应使用趋势型指标。
M1:=4;  //minM1:=3,maxM1:=10
M2:=6;  //minM2:=3,maxM2:=20
M3:=9;  //minM3:=3,maxM3:=30
M4:=13: //minM4:=3,maxM4:=40
M5:=18; //minM5:=3,maxM5:=50
M6:=24; //minM6:=3,maxM6:=60
短1:(EMA(CLOSE,M1)+MA(CLOSE,M1*2)+MA(CLOSE,M1*4))/3;
短2:(EMA(CLOSE,M2)+MA(CLOSE,M2*2)+MA(CLOSE,M2*4))/3;
中1:(EMA(CLOSE,M3)+MA(CLOSE,M3*2)+MA(CLOSE,M3*4))/3;
中2:(EMA(CLOSE,M4)+MA(CLOSE,M4*2)+MA(CLOSE,M4*4))/3;
长1:(EMA(CLOSE,M5)+MA(CLOSE,M5*2)+MA(CLOSE,M5*4))/3;
长2:(EMA(CLOSE,M6)+MA(CLOSE,M6*2)+MA(CLOSE,M6*4))/3;
PRICEOSC Price Oscillator LONG:=26;  //minLONG:=5,maxLONG:=100
SHORT:=12; //minSHORT:=2,maxSHORT:=40
(MA(CLOSE,SHORT)-MA(CLOSE,LONG))/MA(CLOSE,SHORT)*100;
 
SAR 抛物转向
(Stop and Reverse) 1.任何时候都可以使用SAR 为停损点;
2.价格涨跌的速度必须比SAR 升降的速度快,否则必会产生停损信号;
3.SAR 由红色变成绿色时,卖出;
4.SAR 由绿色变成红色时,买进;
5.本设定主要为寻找出现多头停损或空头停损的个股。
N:=10; //minN:=1,maxN:=100
S:=2;  //minS:=1,maxS:=100
MAXP:=20;//minMAXP:=5,maxMAXP:=100
SAR(N,S,MAXP),CIRCLEDOT;
 
SARPB 抛物转向(澎博) N:=10; //minN:=1,maxN:=100
S:=2; //minS:=1,maxS:=100
MAXP:=20; //minMAXP:=5,maxMAXP:=100
SAR_POBO(N,S,MAXP),CIRCLEDOT;
TRTX 三重指数平滑平均线 1.TRIX由下往上交叉其平均线时,为长期买进信号;
2.TRIX由上往下交叉其平均线时,为长期卖出信号;
3.DMA、MACD、TRIX 三者构成一组指标群,互相验证。
N:=12;//minN:=3,maxN:=100
M:=9;//minM:=1,maxM:=100
TR:= EMA(EMA(EMA(CLOSE,N),N),N);
TRIX : (TR-REF(TR,1))/REF(TR,1)*100;
TRMA :  MA(TRIX,M);
UDL 引力线 1.本指标的超买超卖界限值随个股不同而不同,使用者应自行调整;
2.使用时,可列出一年以上走势图,观察其常态性分布范围,然后用参考线设定其超买超卖范围。通常UDL 高于某个极限时,短期股价会下跌;UDL 低于某个极限时,短期股价会上涨;
3.本指标可设参考线。
N1:=3;//minN1:=2,maxN1:=20
N2:=5;//minN2:=2,maxN2:=30
N3:=10;//minN3:=2,maxN3:=60
N4:=20;//minN4:=2,maxN4:=120
M:=6;//minM:=2,maxM:=10;
UDL:(MA(CLOSE,N1)+MA(CLOSE,N2)+MA(CLOSE,N3)+MA(CLOSE,N4))/4;
MAUDL:MA(UDL,M);
VMA 变异平均线 1.股价高于平均线,视为强势;股价低于平均线,视为弱势;
2.平均线向上涨升,具有助涨力道;平均线向下跌降,具有助跌力道;
3.二条以上平均线向上交叉时,买进;
4.二条以上平均线向下交叉时,卖出;
5.VMA 比一般平均线的敏感度更高,消除了部份平均线落后的缺陷。
M1:=6; //minM1:=2,maxM1:=30
M2:=12; //minM2:=6,maxMA2:=60
M3:=30; //minM3:=12,maxM3:=150
M4:=72; //minM4:=30,maxM4:=200
M5:=144;//minM5:=72,maxM5:=250
VV:=(HIGH+OPEN+LOW+CLOSE)/4;
VMA1:MA(VV,M1);
VMA2:MA(VV,M2);
VMA3:MA(VV,M3);
VMA4:MA(VV,M4);
VMA5:MA(VV,M5);
VMACD 量指数平滑异同平均线 SHORT:=12;//minSHORT:=1,maxSHORT:=50
LONG:=26;//minLONG:=20,maxLONG:=100
M:=9;//minM:=3,maxM:=50
DIFF : EMA(VOL,SHORT) - EMA(VOL,LONG);
DEA  : EMA(DIFF,M);
MACD : DIFF-DEA, COLORSTICK;
WTC 加权收盘线 加权收盘线(WeighTed Close),是最高价、最低价和收盘价的加权平均值:
               最高价+最低价+W×收盘价
       WTC = ---------------------------
                      2+W
WTC可以用来代替简单收盘线。
N:=2;//minN:=1,maxN:=60
WTC:(HIGH+LOW+N*CLOSE)/(2+N);
反趋向指标
B3612 三减六日乖离 算法:
B36 收盘价的3日移动平均线与6日均线的差离
B612 收盘价的6日均线与12日均线的差离
用法:
  乖离值围绕多空平衡点零上下波动,正数达到某个程度无法再往上升时,是卖出时机;反之,是买进时机。
  多头走势中,行情回档多半在三减六日乖离达到零附近获得支撑,即使跌破,也很快能够拉回。
B36 : MA(CLOSE,3)-MA(CLOSE,6);
B612 : MA(CLOSE,6)-MA(CLOSE,12);
BIAS 乖离率 1.本指标的乖离极限值随个股不同而不同,使用者可利用参考线设定,固定其乖离范围;
2.当股价的正乖离扩大到一定极限时,股价会产生向下拉回的作用力;
3.当股价的负乖离扩大到一定极限时,股价会产生向上拉升的作用力;
4.本指标可设参考线。
L1:=6;  //minL1:=1,maxL1:=300
L2:=12; //minL2:=1,maxL2:=300
L3:=24; //minL3:=1,maxL3:=300
BIASMA1:=MA(CLOSE,L1);
BIASMA2:=MA(CLOSE,L2);
BIASMA3:=MA(CLOSE,L3);
BIAS1 :(CLOSE-BIASMA1)/BIASMA1*100;
BIAS2 :(CLOSE-BIASMA2)/BIASMA2*100;
BIAS3 :(CLOSE-BIASMA3)/BIASMA3*100;
 
CCI 顺势指标 1.CCI 为正值时,视为多头市场;为负值时,视为空头市场;
2.常态行情时,CCI 波动于±100 的间;强势行情,CCI 会超出±100 ;
3.CCI下破-100 时,买进,直到CCI上穿100时,卖出;
4.CCI上穿100时,放空,直到CCI下破-100 时,回补。
N:=14;minN:=2,maxN:=100
REFLINE: -100, 0, 100;
TYP := (HIGH + LOW + CLOSE)/3;
(TYP-MA(TYP,N))/(0.015*AVEDEV(TYP,N));
DBCD 异同离差乖离率 N:=5;//minN:=1,maxN:=100
M:=16;//minM:=1,maxM:=100
T:=76;//minT:=1,maxT:=100
BIAS:=(C-MA(C,N))/MA(C,N);
DIF:=(BIAS-REF(BIAS,M));
DBCD:SMA(DIF,T,1);
MM:MA(DBCD,5);
 
DPO Detrended Price Oscillator C - REF(MA(CLOSE,20),11);
KD 随机指标 1.指标>80 时,回档机率大;指标<20时,反弹机率大;
2.K在20左右向上交叉D时,视为买进信号;
3.K在80左右向下交叉D时,视为卖出信号;
4.J>100 时,股价易反转下跌;J<0 时,股价易反转上涨;
5.KDJ 波动于50左右的任何信号,其作用不大。
N:=9;//minN:=1,maxN:=100,step:=3
M1:=3;//minM1:=2,maxM1:=40,step:=2
M2:=3;//minM2:=2,maxM2:=40,step:=2
REFLINE: 0, 20, 50, 80, 100;
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1);
D:SMA(K,M2,1);
 
KDJ 随机指标 1.指标>80 时,回档机率大;指标<20时,反弹机率大;
2.K在20左右向上交叉D时,视为买进信号;
3.K在80左右向下交叉D时,视为卖出信号;
4.J>100 时,股价易反转下跌;J<0 时,股价易反转上涨;
5.KDJ 波动于50左右的任何信号,其作用不大。
N:=9;//minN:=1,maxN:=100,step:=3
M1:=3;//minM1:=2,maxM1:=40,step:=2
M2:=3;//minM2:=2,maxM2:=40,step:=2
REFLINE: 0, 20, 50, 80, 100;
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1);
D:SMA(K,M2,1);
J:3*K-2*D;
LW&R LWR威廉指标 N:=9;//minN:=1,maxN:=100
M1:=3;//minM1:=2,maxM1:=40
M2:=3;//minM2:=2,maxM2:=40
RSV:= (HHV(HIGH,N)-CLOSE)/(HHV(HIGH,N)-LLV(LOW,N))*100;
LWR1:SMA(RSV,M1,1);
LWR2:SMA(LWR1,M2,1);
 
ROC 变动速率 1.本指标的超买超卖界限值随个股不同而不同,使用者应自行调整;
2.本指标的超买超卖范围,一般介于±6.5之间;
3.本指标用法请参考MTM 指标用法;
4.本指标可设参考线。
N:=12;//minN:=2,maxN:=120,step:=2
M:=6;//minM:=2,maxM:=60,step:=2
ROC:100*(CLOSE-REF(CLOSE,N))/REF(CLOSE,N);
ROCMA:MA(ROC,M);
 
RSI 相对强弱指标(Relative Strenth Index) 1.RSI>80 为超买,RSI<20 为超卖;
2.RSI 以50为中界线,大于50视为多头行情,小于50视为空头行情;
3.RSI 在80以上形成M头或头肩顶形态时,视为向下反转信号;
4.RSI 在20以下形成W底或头肩底形态时,视为向上反转信号;
5.RSI 向上突破其高点连线时,买进;RSI 向下跌破其低点连线时,卖出。
N1:=6; //minN1:=2,maxN1:=100,step:=3
N2:=12; //minN2:=2,maxN2:=100
N3:=24;//minN3:=2,maxN3:=100
REFLINE: 0, 20, 50, 80, 100;
LC := REF(CLOSE,1);
RSI1:SMA(MAX(CLOSE-LC,0),N1,1)/SMA(ABS(CLOSE-LC),N1,1)*100;
RSI2:SMA(MAX(CLOSE-LC,0),N2,1)/SMA(ABS(CLOSE-LC),N2,1)*100;
RSI3:SMA(MAX(CLOSE-LC,0),N3,1)/SMA(ABS(CLOSE-LC),N3,1)*100;
 
SI Swing Index LC:=REF(C,1);
AA:=ABS(H-LC);
BB:=ABS(L-LC);
CC:=ABS(H-REF(L,1));
DD:=ABS(LC-REF(O,1));
R:=IF(AA>BB AND AA>CC,AA+BB/2+DD/4,IF(BB>CC AND BB>AA,BB+AA/2+DD/4,CC+DD/4));
X:=(C-LC+(C-O)/2+LC-REF(O,1));
SI:16*X/R*MAX(AA,BB);
SLOWKD 慢速KD N:=9;//minN=1,maxN:=100
M1:=3;//minM1:=2,maxM1:=50
M2:=3;//minM2:=2,maxM2:=50;
M3:=5;//minM3,maxM3:=50
RSV:= (CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
FASTK:=SMA(RSV,M1,1);
K:SMA(FASTK,M2,1);
D:SMA(K,M3,1);
 
SRDM 动向速度比率用法同KD指标 N:=30;//minN:=1,maxN:=100
DMZ:=IF((H+L)<=(REF(H,1)+REF(L,1)),0,MAX(ABS(H-REF(H,1)),ABS(L-REF(L,1))));
DMF:=IF((H+L)>=(REF(H,1)+REF(L,1)),0,MAX(ABS(H-REF(H,1)),ABS(L-REF(L,1))));
ADMZ:=MA(DMZ,10);
ADMF:=MA(DMF,10);
SRDM:IF(ADMZ>ADMF,(ADMZ-ADMF)/ADMZ,IF(ADMZ=ADMF,0,(ADMZ-ADMF)/ADMF));
ASRDM:SMA(SRDM,N,1);
VROC 量变动速率 N:=12;//minN:=2,maxN:=300
(VOL-REF(VOL,N))/REF(VOL,N)*100;
VRSI 量相对强弱 N:=6;//minN:=1,maxN:=100
SMA(MAX(VOL-REF(VOL,1),0),N,1)/SMA(ABS(VOL-REF(VOL,1)),N,1)*100;
W&R 威廉指标(William's %R) 1.WR 波动于0~-100,0 置于顶部,-100 置于底部;
2.本指标以-50为中轴线,高于-50视为股价转强;低于-50视为股价转弱;
3.本指标高于-20后再度向下跌破-20卖出;低于-80后再度向上突破-80买进;
4.WR 连续触顶3~4次,股价向下反转机率大;连续触底3~4次,股价向上反转机率大。
N:=14;//minN:=2,maxN:=100,step:=3
100*(HHV(HIGH,N)-CLOSE)/(HHV(HIGH,N)-LLV(LOW,N));
 
能量指标
ARBR 人气意愿指标 N:=26;//minN:=2,maxN:=300
AR : SUM(HIGH-OPEN,N)/SUM(OPEN-LOW,N)*100;
BR : SUM(MAX(0,HIGH-REF(CLOSE,1)),N)/
     SUM(MAX(0,REF(CLOSE,1)-LOW),N)*100;
 
CR CR能量指标 1.CR>400时,其10日平均线向下滑落,视为卖出信号;CR<40买进;
2.CR 由高点下滑至其四条平均线下方时,股价容易形成短期底部;
3.CR 由下往上连续突破其四条平均线时,为强势买进点;
4.CR指标越低,买入越安全;
5.CR 除了预测价格的外,最大的作用在于预测时间;
6.BR、AR、CR、VR 四者合为一组指标群,须综合搭配使用。
N:=26;  //minN:=5,maxN:=300
M1:=5;  //minM1:=1,maxM1:=100
M2:=10; //minM2:=1,maxM2:=100
M3:=20; //minM3:=1,maxM3:=100
M4:=62; //minM4:=1,maxM4:=100
MID := (HIGH+LOW+CLOSE)/3;
CR:SUM(MAX(0,HIGH-REF(MID,1)),N)/SUM(MAX(0,REF(MID,1)-L),N)*100;
MA1:REF(MA(CR,M1),M1/2.5+1);
MA2:REF(MA(CR,M2),M2/2.5+1);
MA3:REF(MA(CR,M3),M3/2.5+1);
MA4:REF(MA(CR,M4),M4/2.5+1);
 
JYJL 参考均量
TJCJL 太极成交量
VR VR容量比率 1.VR>450,市场成交过热,应反向卖出;
2.VR<40 ,市场成交低迷,人心看淡的际,应反向买进;
3.VR 由低档直接上升至250,股价仍未遭受阻力,此为大行情的前兆;
4.VR 除了与PSY为同指标群外,尚须与BR、AR、CR同时搭配研判
N:=26;minN:=5,maxN:=300
LC:=REF(CLOSE,1);
SUM(IF(CLOSE>LC,VOL,0),N)/
SUM(IF(CLOSE<=LC,VOL,0),N)*100;
ZX 重心线 重心线指标,重心线是由重心价连接而成的曲线,反映历史平均价位,
对于指数计算公式为:
  ZX = 成交金额/成交量。
对个股而言:
         最高指数+最低指数+收盘指数
  ZX = ————————————————
                      3
类似于不加权平均指数。
AV:0.01*AMOUNT/VOL;
量价指标
AMV 成本价均线 成本价均线不同于一般移动平均线系统,成本价均线系统首次将成交量引入均线系统,充分提高均线系统的可靠性。同样对于成本价均线可以使用月均线系统(5,10,20,250)和季均线系统(20,40,60,250),另外成本价均线还可以使用自身特有的均线系统(5,13,34,250),称为市场平均建仓成本均线,简称成本价均线。在四个均线中参数为250的均线为年度均线,为行情支撑均线。成本均线不容易造成虚假信号或骗线,比如某日股价无量暴涨,移动均线会大幅拉升,但成本均线却不会大幅上升,因为在无量的情况下市场持仓成本不会有太大的变化。依据均线理论,当短期均线站在长期均线之上时叫多头排列,反之就叫空头排列。短期均线上穿长期均线叫金叉,短期均线下穿长期均线叫死叉。均线的多头排列是牛市的标志,空头排列是熊市的标志。均线系统一直是市场广泛认可的简单而可靠的分析指标,其使用要点是尽量做多头排列的股票,回避空头排列的股票。34日成本线是市场牛熊的重要的分水岭。一旦股价跌破34日成本线,则常常是最后的出逃机会。
M1:=5;  //minM1:=2,maxM1:=120
M2:=13; //minM2:=2,maxM2:=120
M3:=34; //minM3:=2,maxM3:=120
M4:=60; //minM4:=2,maxM4:=120
AMOV:=VOL*(OPEN+CLOSE)/2;
AMV1:SUM(AMOV,M1)/SUM(VOL,M1);
AMV2:SUM(AMOV,M2)/SUM(VOL,M2);
AMV3:SUM(AMOV,M3)/SUM(VOL,M3);
AMV4:SUM(AMOV,M4)/SUM(VOL,M4);
 
ASI 振动升降指标 1.ASI 又名「实质线」,是一条比收盘价线更能代表真实行情的曲线;
2.ASI 突破前一波高点后,第二天股价必突破前一波高点;
3.ASI 跌破前一波低点后,第二天股价必跌破前一波低点;
4.ASI 一般与股价走势维持同步波动,并非每一次行情都有领先作用,因此,使用者必须花费一些时间搜寻产生领先信号的个股。
LC:=REF(CLOSE,1);
AA:=ABS(HIGH-LC);
BB:=ABS(LOW-LC);
CC:=ABS(HIGH-REF(LOW,1));
DD:=ABS(LC-REF(OPEN,1));
R:=IF(AA>BB AND AA>CC,AA+BB/2+DD/4,IF(BB>CC AND BB>AA,BB+AA/2+DD/4,CC+DD/4));
X:=(CLOSE-LC+(CLOSE-OPEN)/2+LC-REF(OPEN,1));
SI:=16*X/R*MAX(AA,BB);
ASI:SUM(SI,0);
OBV 能量潮 1.股价一顶比一顶高,而OBV 一顶比一顶低,暗示头部即将形成;
2.股价一底比一底低,而OBV 一底比一底高,暗示底部即将形成;
3.OBV 突破其N字形波动的高点次数达5 次时,为短线卖点;
4.OBV 跌破其N字形波动的低点次数达5 次时,为短线买点;
SUM(IF(CLOSE>REF(CLOSE,1),VOL,IF(CLOSE<REF(CLOSE,1),-VOL,0)),0);
PVT Price/Volume Trend SUM((CLOSE-REF(CLOSE,1))/REF(CLOSE,1)*VOL,0);
SOBV 能量潮 SUM(IF(ISUP,VOL,IF(ISDOWN,-VOL,0)),0);
 
VPT 量价曲线
WVAD 威廉变异离散量 1.WVAD由下往上穿越0 轴时,视为长期买进信号;
2.WVAD由上往下穿越0 轴时,视为长期卖出信号; 
3.当ADX 低于±DI时,本指标失去效用;
4.长期使用WVAD指标才能获得最佳利润;
5.本指标可与EMV 指标搭配使用。
(CLOSE-OPEN)/(HIGH-LOW)*VOL;
压力支撑指标
BBIBOLL 多空布林带 BBI算法:
3日平均价加6日平均价加12日平均价加24日平均价,其和除以四。
用法:
1.为BBI与BOLL的迭加;
2.高价区收盘价跌破BBI线,卖出信号;
3.低价区收盘价突破BBI线,买入信号;
4.BBI线向上,股价在BBI线之上,多头势强;
5.BBI线向下,股价在BBI线之下,空头势强。
N:=11;//minN:=1,maxN:=100
P:=6;//minP:=0,maxP:=20
BBI:(MA(CLOSE,3)+MA(CLOSE,6)+MA(CLOSE,12)+MA(CLOSE,24))/4;
UPR:BBI+P*STD(BBI,N);
DWN:BBI-P*STD(BBI,N);
 
BOLL 布林线 1.股价上升穿越布林线上限时,回档机率大;
2.股价下跌穿越布林线下限时,反弹机率大;
3.布林线震动波带变窄时,表示变盘在即;
4.这里对宽度作了取整处理,一律乘以10,原来范围:0.1-10;现在范围:1-100;
N:=26;//minN:=5,maxN:=300,step:=3
P:=2;minP:=0.1,maxP:=10,step:=2
MID :  MA(CLOSE,N);
UPPER: MID + P*STD(CLOSE,N);
LOWER: MID - P*STD(CLOSE,N);
 
CDP 逆势操作 PT  := REF(HIGH,1)-REF(LOW,1);
CDP : (HIGH + LOW + CLOSE)/3;
AH  : CDP + PT;
AL  : CDP - PT;
NH  : 2*CDP-LOW;
NL  : 2*CDP-HIGH;
 
ENE 轨道线 1.股价上升穿越轨道线上限时,回档机率大;
2.股价下跌穿越轨道线下限时,反弹机率大;
3.股价波动于轨道线内时,代表常态行情,此时,超买超卖指标可发挥效用;
4.股价波动于轨道线外时,代表脱轨行情,此时,应使用趋势型指标。
N:=25;//minN:=2,maxN:=120
M1:=6;//minM1:=2,maxM1:=120
M2:=6;//minM2:=2,maxM2:=120
UPPER:(1+M1/100)*MA(CLOSE,N);
LOWER:(1-M2/100)*MA(CLOSE,N);
ENE:(UPPER+LOWER)/2;
 
ENV Envalops N:=14;//minN:=2,maxN:=300
UPPER : MA(CLOSE,N)*1.06;
LOWER : MA(CLOSE,N)*0.94;
 
MIKE 麦克指标 1.MIKE指标共有六条曲线,上方三条压力线,下方三条支撑线;
2.当股价往压力线方向涨升时,其下方支撑线不具参考价值;
3.当股价往支撑线方向下跌时,其上方压力线不具参考价值。
N:=12;//minN:=1,maxN:=200
TYP:=(HIGH+LOW+CLOSE)/3;
LL:=LLV(LOW,N);
HH:=HHV(HIGH,N);
WR:TYP+(TYP-LL);
MR:TYP+(HH-LL);
SR:2*HH-LL;
WS:TYP-(HH-TYP);
MS:TYP-(HH-LL);
SS:2*LL-HH;
 
RAIL 火车轨 M1:=30;//minM1:=1,maxM1:=100
M2:=30;//minM2:=1,maxM2:=100
MA_HIGH:MA(HIGH,30); 
MA_LOW:MA(LOW,30);
超买超卖指标
ADTM 动态买卖气指标 N:=23;//minN:=1,maxN:=100
M:=8;//minM:=1,maxM:=100
DTM:=IF(O<=REF(O,1),0,MAX((H-O),(O-REF(O,1))));
DBM:=IF(O>=REF(O,1),0,MAX((O-L),(O-REF(O,1))));
STM:=SUM(DTM,N);
SBM:=SUM(DBM,N);
ADTM:IF(STM>SBM,(STM-SBM)/STM,IF(STM=SBM,0,(STM-SBM)/SBM));
MA1:MA(ADTM,M);
 
BRAR 情绪指标 1.BR>400,暗示行情过热,应反向卖出;BR<40 ,行情将起死回生,应买进;
2.AR>180,能量耗尽,应卖出;AR<40 ,能量已累积爆发力,应买进;
3.BR 由300 以上的高点下跌至50以下的水平,低于AR 时,为绝佳买点;
4.BR、AR、CR、VR 四者合为一组指标群,须综合搭配使用。
M:=26;//minM:=2,maxM:=120
N:=26;//minN:=2,maxN:=120
//额外Y轴分界:40、300、60、150
BR:SUM(MAX(0,HIGH-REF(CLOSE,1)),M)/SUM(MAX(0,REF(CLOSE,1)-LOW),M)*100;
AR:SUM(HIGH-OPEN,N)/SUM(OPEN-LOW,N)*100;
MOM 动量线 N:=12;//minN:=1,maxN:=999
M:=6;//minM:=1,maxM:=999
MOM1:CLOSE-REF(CLOSE,N);
MOM2:MA(MOM1,M);
MTM MTM动力指标 MTM线 :当日收盘价与N日前的收盘价的差;
MTMMA线:对上面的差值求N日移动平均;
参数:N 间隔天数,也是求移动平均的天数,一般取6
用法:
1.MTM从下向上突破MTMMA,买入信号;
2.MTM从上向下跌破MTMMA,卖出信号;
3.股价续创新高,而MTM未配合上升,意味上涨动力减弱;
4.股价续创新低,而MTM未配合下降,意味下跌动力减弱;
5.股价与MTM在低位同步上升,将有反弹行情;反之,从高位同步下降,将有回落走势。
N:=12;//minN:=2,maxN:=120,step:=2
M:=6;//minM:=2,maxM:=60,step:=2
MTM : CLOSE-REF(CLOSE,N);
MTMMA : MA(MTM,M);
 
OSC 变动速率线 1.OSC 向上交叉其平均线时,买进;OSC 向下交叉其平均线时卖出;
2.OSC 在高水平或低水平与股价产生背离时,应注意股价随时有反转的可能;
3.OSC 的超买超卖界限值随个股不同而不同,使用者应自行调整
N:=20;//minN:=2,maxN:=100
M:=6;//minM:=2,maxM:=60
OSC:100*(CLOSE-MA(CLOSE,N));
MAOSC:EMA(OSC,M);
PSY 心理线 1.PSY>75,形成M头时,股价容易遭遇压力;
2.PSY<25,形成W底时,股价容易获得支撑;
3.PSY 与VR 指标属一组指标群,须互相搭配使用。
N:=12;//minN:=2,maxN:=100,step:=20
M:=6;//minM:=0,maxM:=40,step:=1
PSY:COUNT(CLOSE>REF(CLOSE,1),N)/N*100;
PSYMA:MA(PSY,M)
WAD 威廉多空力度线 1.股价一顶比一顶高,而WAD 一顶比一顶低,暗示头部即将形成;
2.股价一底比一底低,而WAD 一底比一底高,暗示底部即将形成;
3.WAD 与OBV、ADL同属一组指标群,使用时应综合研判。
M:=30;//minM:=2,maxM:=120
MIDA:=CLOSE-MIN(REF(CLOSE,1),LOW);
MIDB:=IF(CLOSE<REF(CLOSE,1),CLOSE-MAX(REF(CLOSE,1),HIGH),0);
WAD:SUM(IF(CLOSE>REF(CLOSE,1),MIDA,MIDB),0);
MAWAD:MA(WAD,M);
WR 威廉指标 1.WR 波动于0~-100,0 置于顶部,-100 置于底部;
2.本指标以-50为中轴线,高于-50视为股价转强;低于-50视为股价转弱;
3.本指标高于-20后再度向下跌破-20卖出;低于-80后再度向上突破-80买进;
4.WR 连续触顶3~4次,股价向下反转机率大;连续触底3~4次,股价向上反转机率大。
N:=10;//minN:=2,maxN:=100,step:=3
N1:=6;//minN1:=2,maxN1:=100
LL:=-80;//minLL:=-100,maxLL:=-60,step:=3
LH:=-20;//minLH:=-40,maxLH:=0,step:=3
HHVHIGH1:=HHV(HIGH,N);
HHVHIGH2:=HHV(HIGH,N1);
WR1:-100*(HHVHIGH1-CLOSE)/(HHVHIGH1-LLV(LOW,N));
WR2:-100*(HHVHIGH2-CLOSE)/(HHVHIGH2-LLV(LOW,N1));
摆动指标
AD Accumulation/Distribution SUM(((CLOSE-LOW)-(HIGH-CLOSE))/(HIGH-LOW)*VOL,0);
 
ATR 真实波幅 N:=15;minN:=1,maxN:=300
TR : MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));
ATR : MA(TR,N);
 
MI 动量指标 N:=12;//minN:=1,maxN:=100
A:C-REF(C,N);
MI:SMA(A,N,1);
 
MICD 异同离差动力指数 N:=3;//minN:=1,maxN:=100
N1:=10;//minN1:=1,maxN1:=100
N2:=20;//minN2:=1,maxN2:=100
MI:=C-REF(C,1);
AMI:=SMA(MI,N,1);
DIF:MA(REF(AMI,1),N1)-MA(REF(AMI,1),N2);
MICD:SMA(DIF,10,1);
 
RC 变化率指数 N:=50;//minN:=1,maxN:=100
RC:=C/REF(C,N);
ARC:SMA(REF(RC,1),N,1);
 
RCCD 异同离差变化率指数 N:=59;//minN:=1,maxN:=100
N1:=21;//minN1:=1,maxN1:=100
N2:=28;//minN2:=1,maxN2:=100
RC:=C/REF(C,N);
ARC:=SMA(REF(RC,1),N,1);
DIF:MA(REF(ARC,1),N1)-MA(REF(ARC,1),N2);
RCCD:SMA(DIF,N,1);
 
SRMI MI修正指标 N:=9;//minN:=1,maxN:=100
IF(C<REF(C,N),(C-REF(C,N))/REF(C,N),IF(C=REF(C,N),0,(C-REF(C,N))/C));
 
特色指标
DKX 多空线 M:=10;//minM:=1,maxM:=250
A:=(3*C+L+O+H)/6;
B:(20*A+19*REF(A,1)+18*REF(A,2)+17*REF(A,3)+16*REF(A,4)+15*REF(A,5)+14*REF(A,6)
+13*REF(A,7)+12*REF(A,8)+11*REF(A,9)+10*REF(A,10)+9*REF(A,11)+8*REF(A,12)
+7*REF(A,13)+6*REF(A,14)+5*REF(A,15)+4*REF(A,16)+3*REF(A,17)+2*REF(A,18)+
REF(A,20))/210;
D:MA(B,M);
 
JGBDL 价格波动率 N:=60;//minN:=1,maxN:=250
M:=120;minM:=1,maxM:=250
RDR:=LN(C/REF(C,1));
VR:STD(RDR,N)*100;
VRMA:MA(VR,M);
 
LON 长线指标 N:=10;minN:=1,maxN:=1000
TB:=IF(HIGH>REF(CLOSE,1),HIGH-REF(CLOSE,1)+CLOSE-LOW,CLOSE-LOW);
TS:=IF(REF(CLOSE,1)>LOW,REF(CLOSE,1)-LOW+HIGH-CLOSE,HIGH-CLOSE);
VOL_:=(TB-TS)*VOL/(TB+TS)/10000;
VOL_0:=DMA(VOL_,0.1);
VOL_1:=DMA(VOL_,0.05);
RES1:=VOL_0-VOL_1;
LON:SUM(RES1,0),COLORSTICK;
LON;
MA1:MA(LON,N);
 
NDB 脑电波 脑电波是判断主力虚实的工具
市场倾向于认为开盘价和收盘价是多空双方共同认可的价格,如果以收盘价作为多空双方的平衡点,那么,收盘价之上的部分是空头的成果,收盘价之下的部分是多头的成果,二者的差就是当天多空双方的力量对比.如果多头占优势,脑电波就不断上升,如果空头占优势,脑电波就不断下降.所以,脑电波上升的股票可以继续持有或者买进,脑电波下降的股票应该卖出.
M1:=5;//minM1:=2,maxM1:=120
M2:=10;//minM2:=2,maxM2:=120
HH:=IF(C/REF(C,1)>1.098 AND L>REF(H,1),2*C-REF(C,1)-H,2*C-H-L);
//V1:=BARSCOUNT(C);
//V2:=2*REF(C,V1)-REF(H,V1)-REF(L,V1);
V2:=2*C[1]-H[1]-L[1];
DK:SUM(HH,0)+V2;
MDK5:MA(DK,M1);
MDK10:MA(DK,M2);
 
PUCU 逆时钟曲线 1.图表的曲线上有一个箭头,该处代表目前价量的位置;
2.曲线由绿变成红色时,视为买进信号;
3.曲线由红变成绿色时,视为卖出信号。
N:=24;//minN:=2,maxN:=200
PU:MA(CLOSE,N);
CU:MA(VOL,N);
QHLSR 阻力指标 QHL:=(C-REF(C,1))-(VOL-REF(VOL,1))*(REF(H,1)-REF(L,1))/REF(VOL,1);
A:=SUM(IF(QHL>0,QHL,0),5);
E:=SUM(IF(QHL>0,QHL,0),10);
B:=ABS(SUM(IF(QHL<0,QHL,0),5));
F:=ABS(SUM(IF(QHL<0,QHL,0),10));
D:=A/(A+B);
G:=E/(E+F);
QHL5: IF(SUM(IF(QHL>0,1,0),5)=5,1,IF(SUM(IF(QHL<0,1,0),5)=5,0,D)) ;
QHL10:G;
 
SHORT 短线指标 N:=10;//minN:=1,maxN:=1000
TB:=IF(HIGH>REF(CLOSE,1),HIGH-REF(CLOSE,1)+CLOSE-LOW,CLOSE-LOW);
TS:=IF(REF(CLOSE,1)>LOW,REF(CLOSE,1)-LOW+HIGH-CLOSE,HIGH-CLOSE);
VOL_:=(TB-TS)*VOL/(TB+TS)/10000;
VOL_0:=DMA(VOL_,0.1);
VOL_1:=DMA(VOL_,0.05);
SHORT:VOL_0-VOL_1,COLORSTICK;
SHORT;
MA1:MA(SHORT,N);
 
XS 薛斯通道 薛斯通道的研判法则:
1.长期大通道是反映该股票的长期趋势状态,趋势有一定惯性,延伸时间较长,反映股票大周期,可以反握股票整体趋势,适于中长线投资;
 2.短期小通道反映该股票的短期走势状态,包容股票的涨跌起伏,有效地滤除股票走势中的频繁振动,但保留了股票价格在大通道内的上下波动,反映股票小周期,适于中短线炒作;
 3.长期大通道向上,即大趋势总体向上 ,此时短期小通道触及(或接近长期大通道底部时,即买压增大,有反弹的可能。而短期小通道触及长期大通道顶部,既卖压增大,形态出现回调或盘整,有向长期大通道靠近的趋势。如果K线走势与短期小通道走势亦吻合得很好,那么更为有效;
 4.长期大通道向上,而短期小通道触及长期大通道顶部,此时该股为强力拉长阶段,可适当观望,待短期转平或转头向下时,为较好出货点,但穿透区为风险区应密切注意反转信号,随时出货;
 5.长期大通道向下,即大趋势向下,此时短期小通道或股价触顶卖压增加,有再次下跌趋势。而触底形态即买压增大,有缓跌调整或止跌要求,同时价格运动将趋向靠近长期大通道上沿。回调宜慎重对待,待确认反转信号后方可买入;
 6.长期大通道向下,而短期小通道向下穿透长期大通道底线,此时多为暴跌过程,有反弹要求,但下跌过程会持续,不宜立即建仓,应慎重,待长期大通道走平且有向上趋势,短期小通道回头向上穿回时,是较好的低位建仓机会;
 7.当长期大通道长期横向走平时,为盘整行情,价格沿通道上下震荡,此时为调整、建仓、洗盘阶段,预示着下一轮行情的出现,短线炒家可逢高抛出,逢低买入。若以短期小通道强力上穿长期大通道,且长期大通道向上转向,表明强劲上涨行情开始。若以短期小通道向下穿透长期大通道,且长期大通道向下转向,表明下跌将继续。
N1:=30;//minN1:=2,maxN1:=100
N2:=3;//minN2:=2,maxN2:=100
P1:=15;//minP1:=1,maxP1:=100
P2:=3;//minP2:=1,maxP2:=100
UPPERL: MA(HIGH,N1)*(1+P1/100);
UPPERS: MA(HIGH,N2)*(1+P2/100);
LOWERL: MA(LOW,N1)*(1-P1/100);
LOWERS: MA(LOW,N2)*(1-P2/100);
 
ZQLLBDX 债券利率波动性 N:=60;//minN:=1,maxN:=500
M:=120;//minM:=1,maxM:=250
Y:=BONDYIELD()*100;
RDR:=LN(Y/REF(Y,1));
VR:STD(RDR,N)*100;
VRMA:MA(VR,M);
 
ZQSYL 债券收益率 Y:BONDYIELD();
qqbdl 期权隐含波动率、历史波动率曲线 N:=60;//minN:=1,maxN:=300
隐含波动率:IMPLIEDVOLATILITY(N,RISKFREERATE);
历史波动率:VOLATILITY(N,OPTIONINFO(01));
 
其它指标
ACCER 幅度涨速 N:=8;//minN:=2,maxN:=100
ACCER:SLOPE(CLOSE,N)/CLOSE;
ACD 升降线 M:=20;//minM:=2,maxM:=100
LC:=REF(CLOSE,1);
DIF:=CLOSE-IF(CLOSE>LC,MIN(LOW,LC),MAX(HIGH,LC));
ACD:SUM(IF(CLOSE=LC,0,DIF),0);
MAACD:EMA(ACD,M);
 
CCIZT CCI主图 TYP:=(HIGH+LOW+CLOSE)/3;
CCI:=(TYP-MA(TYP,13))/(0.015*AVEDEV(TYP,13));
STICKLINE(CCI>=0,O,C,4,1),COLORRED;
STICKLINE(CCI>=0,O,L,0.1,0),COLORRED;
STICKLINE(CCI>=0,C,H,0.1,0),COLORRED;
STICKLINE(CCI<0,O,C,4,0),COLORCYAN;
STICKLINE(CCI<0,O,H,0.1,0),COLORCYAN;
STICKLINE(CCI<0,C,L,0.1,0),COLORCYAN;
DRAWTEXT(CROSS(CCI,-200) AND CCI>REF(CCI,1),L,'平空'),COLORGREEN;
DRAWTEXT(CROSS(200,CCI) AND CCI<REF(CCI,1),H,'平多'),COLORYELLOW;
DRAWTEXT(CROSS(CCI,100) AND CCI>REF(CCI,1),L,'加多'),COLORYELLOW;
DRAWTEXT(CROSS(-100,CCI) AND CCI<REF(CCI,1),H,'加空'),COLORGREEN
 
CHO 佳庆指标
CYQKL 博弈K线长度
JAX 济安线
MACDBL MACD背离 DIFF:EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:EMA(DIFF,9),LINETHICK1,COLORFFFF00; {QDIF:IF(DEA,DIF,0),COLORRED,LINETHICK2;}
QDIF:DIFF,COLORRED,LINETHICK2; D:=BACKSET(DIFF<REF(DIFF,1),2);
{RDIF:IF(D ,DIF,0),COLOR33FF33,LINETHICK2;}
PARTLINE(D,DIFF),COLOR33FF33,LINETHICK2;
MACD:(DIFF-DEA)*2;
STICKLINE(MACD>=0 AND MACD>=REF(MACD,1),0,MACD,0,0),COLORRED;
STICKLINE(MACD>=0 AND MACD<=REF(MACD,1),0,MACD,0,0),COLORGREEN;
STICKLINE(MACD<=0 AND MACD>=REF(MACD,1),0,MACD,0,0),COLORFF00FF;
STICKLINE(MACD<=0 AND MACD<=REF(MACD,1),0,MACD,0,0),COLOR00FFFF;
多转空:=((((LLV(MACD,4)>0) AND (MACD<REF(MACD,1))) AND (REF(MACD,1)>REF(MACD,2))) AND (REF(MACD,2)>REF(MACD,3)));
空转多:=((((HHV(MACD,4)<0) AND (MACD>REF(MACD,1))) AND (REF(MACD,1)<REF(MACD,2))) AND (REF(MACD,2)<REF(MACD,3)));
DRAWICON(多转空,MACD*1.002,5);
DRAWICON(空转多,MACD*0.998,4);
{DRAWGBK(1,COLORRGB(0,0,30),COLORRGB(0,0,100),1);}
A1:=BARSLAST(REF(CROSS(DIFF,DEA),1));
B1:=REF(C,A1+1)>C AND REF(DIFF,A1+1)<DIFF AND CROSS(DIFF,DEA);
DRAWTEXT(IF(B1>0,1,0),DEA,'底背离');
C1:=BARSLAST(REF(CROSS(DEA,DIFF),1));
D1:=REF(C,C1+1)<C AND REF(DIFF,C1+1)>DIFF AND CROSS(DEA,DIFF);
DRAWTEXT(IF(D1>0,1,0),DEA,'顶背离');
 
TF03MRTL TF03买入套利 PTF:="040203$CLOSE";
DS:="040203$HISEXPDAYS";
DT:="040203$HISEXPDATE";
NDT:=EXPIREDDATE('040203');
SY:=BONDSINFO(08)*DS/365;
ZHYZ:=BONDSINFO(40);
JC:IF(DT=NDT AND ZHYZ>0,PTF*ZHYZ-C+SY,0);
Y:JC*365/DS;
 
TF06MRTL TF06买入套利 PTF:="040206$CLOSE";
DS:="040206$HISEXPDAYS";
DT:="040206$HISEXPDATE";
NDT:=EXPIREDDATE('040206');
SY:=BONDSINFO(08)*DS/365;
ZHYZ:=BONDSINFO(41);
JC:IF(DT=NDT AND ZHYZ>0,PTF*ZHYZ-C+SY,0);
Y:JC*365/DS;
 
TF09MRTL TF09买入套利 PTF:="040209$CLOSE";
DS:="040209$HISEXPDAYS";
DT:="040209$HISEXPDATE";
NDT:=EXPIREDDATE('040209');
SY:=BONDSINFO(08)*DS/365;
ZHYZ:=BONDSINFO(42);
JC:IF(DT=NDT AND ZHYZ>0,PTF*ZHYZ-C+SY,0);
Y:JC*365/DS;
 
TF12MRTL TF12买入套利 PTF:="040212$CLOSE";
DS:="040212$HISEXPDAYS";
DT:="040212$HISEXPDATE";
NDT:=EXPIREDDATE('040212');
SY:=BONDSINFO(08)*DS/365;
ZHYZ:=BONDSINFO(43);
JC:IF(DT=NDT AND ZHYZ>0,PTF*ZHYZ-C+SY,0);
Y:JC*365/DS;
 
WAVE 波浪分析
DKFMT 多空分明主图 VAR1A:=LLV(LOW,21);
VAR2A:=HHV(HIGH,21);
AK1:=EMA((((CLOSE - VAR1A) / (VAR2A - VAR1A)) * 100),5);
AK:=EMA((((CLOSE - VAR1A) / (VAR2A - VAR1A)) * 50),13);
AB:=CROSS(AK1,AK);
DRAWTEXT((AB=1),L,'建多'),COLORYELLOW;
VAR3AA:=IF((CLOSE>REF(CLOSE,1)),88,0);
VAR4AA:=IF(((CLOSE)/(REF(CLOSE,1))>1.05) AND ((HIGH)/(CLOSE)<1.01) AND (VAR3AA>0),91,0);
STICKLINE(C>=O OR (C=O AND C>REF(C,1)),O,C,4,1),COLORRED;
STICKLINE((C>=O AND C<>H) OR (C=O AND C>REF(C,1)),C,H,0.1,0),COLORRED;
STICKLINE((C>=O AND L<>O) OR (C=O AND C>REF(C,1)),L,O,0.1,0),COLORRED;
STICKLINE(C<O OR (C=O AND C>REF(C,1)),O,C,4,0),COLORCYAN;
STICKLINE((C<O AND C<>H) OR (C=O AND C>REF(C,1)),C,H,0.1,1),COLORCYAN;
STICKLINE((C<O AND L<>O) OR (C=O AND C>REF(C,1)),L,O,0.1,1),COLORCYAN;
DRAWTEXT(FILTER((VAR4AA>90),45),L,'★大胆多 '),COLOR00FFFF;
VAR1:=(CLOSE-LLV(LOW,36))/(HHV(HIGH,36)-LLV(LOW,36))*100;
VAR2:=SMA(VAR1,3,1);
VAR3:=SMA(VAR2,3,1);
VAR5:=CROSS(SMA(VAR2,3,1),SMA(VAR3,3,1)) AND SMA(VAR2,3,1)<20;
DRAWTEXT(FILTER(VAR5,10)=1,LOW,'抄底'),COLORYELLOW;
VARA:=LLV(LOW,35);
VARB:=HHV(HIGH,30);
VARC:=EMA((CLOSE-VARA)/(VARB-VARA)*4,4)*25;
DRAWTEXT(IF(CROSS(87.5,VARC),87,0),H,'空'),COLOR00FF00
条件选股公式
A001 低市盈率选股 N:=20;minN:=5,maxN:=30,step:=1
DYNAINFO(27)<=N;
举牌概念股 N:=50;//minN:=1,maxN:=100,step:=1
FINANCE(7)/FINANCE(1)>N/100;
主营业务利润率选股 N:=20,minN:=1,maxN:=100,step:=1
FINANCE(21)/FINANCE(20)>N/100;
A004 市净率选股 N:=5;//minN:=1,maxN:=50,step:=1
CLOSE/FINANCE(33)<N;
A005 次新股选股 N:=60;minN:=1,maxN:=200,step:=1
BARSCOUNT(CLOSE)<N;
上市时段选股 Y:=2001;minY:=1990,maxY:=2050,step:=2
M1:=1;//minM1:=1,maxM1:=12,step:=1
M2:=5;//minM2:=1,maxM2:=12,step:=1
COUNT(BARSCOUNT(CLOSE)=1 AND YEAR=Y AND MONTH>=M1 AND MONTH<=M2,0);
ASRD 浮筹比例(大于) P1:=90;//minP1:=0,maxP1:=100,step:=1
ASR:(WINNER(CLOSE*1.1)-WINNER(CLOSE*0.9))>P1*WINNER(HHV(HIGH,0))*100;
ASRX 浮筹比例(小于) P1:=20;//minP1:=0,maxP1:=100,step:=1
ASR:(WINNER(CLOSE*1.1)-WINNER(CLOSE*0.9))<P1*WINNER(HHV(HIGH,0))*100;
B001 委比选股 N:=50;//minN:=0,maxN:=1000,step:=1
DYNAINFO(15)>N;
B002 委差选股 N:=1000;//minN:=1,maxN:=9999,step:=1
选择当前委比大于等于N的股票,委比越大则说明买盘越强劲,(但这也不是绝对的,有可能被人为操纵).
DYNAINFO(16)>N;
B003 内外盘选股(上涨) 选择(委买量-委卖量)的差为正数并且大于N手的股票,差值越大买盘越强.
DYNAINFO(22)>DYNAINFO(23) AND CLOSE>REF(CLOSE,1);
B004 内外盘选股(下跌) 内盘大于外盘,股票仍上涨。这类股票存在一定异动,有庄家活动的可能.
DYNAINFO(22)>DYNAINFO(23) AND CLOSE<REF(CLOSE,1);
B005 股价-均价选股 外盘大于内盘,股价仍下跌.这类股票存在一定异动,有庄家活动的可能.
DYNAINFO(7)>DYNAINFO(11);
BIAS买入 乖离率买入条件选股 N:=12;//minN:=1,maxN:=100,step:=1
LL:=6;//minLL:=0,maxLL:=40,step:=1
(CLOSE-MA(CLOSE,N))/MA(CLOSE,N)*100+LL<0;
BIAS卖出 乖离率卖出条件选股 N:=12;//minN:=1,maxN:=100,step:=1
M:=12;//minM:=1,maxM:=100,step:=1
100*(CLOSE-MA(CLOSE,N))/MA(CLOSE,N)>M;
BOLL买入 布林带买入条件选股 收盘价由下向上穿越BOLL下轨(买入)
N:=20;//minN:=5,maxN:=100,step:=1
S:=2;//minS:=0,maxS:=10,step:=1
MID :=  MA(CLOSE,N);
UPPER:= MID+S*STD(CLOSE,N);
LOWER:= MID-S*STD(CLOSE,N);
CROSS(CLOSE,LOWER);
BOLL卖出 布林带卖出条件选股 收盘价向下突破上限upper,为卖出时机
N:=20;//minN:=5,maxN:=100,step:=1
PP:=2;//minPP:=0,maxPP:=10,step:=1
MID :=  MA(CLOSE,N);
UPPER:= MID+PP*STD(CLOSE,N);
LOWER:= MID-PP*STD(CLOSE,N);
CROSS(UPPER,CLOSE);
C101 N日内创新高 分时图中目前股价高于均价的股票
N:=10;//minN:=1,maxN:=250,step:=1
HHV(HIGH,N)=HHV(HIGH,0) AND BARSCOUNT(CLOSE)>=N;
C102 N日内创新低 N:=10;//minN:=1,maxN:=60,step:=1
LLV(LOW,N)=LLV(LOW,0) AND BARSCOUNT(CLOSE)>=N;
C103 M日内阴线多于阳线 N:=60;//minN:=50,maxN:=100,step:=1
M:=30;//minM:=3,maxM:=300,step:=1
COUNT(OPEN>CLOSE,M)/M >= N/100;
C104 M日内阳线多于阴线 N:=60;//minN:=50,maxN:=100,step:=1
M:=30;//minM:=3,maxM:=300,step:=1
COUNT(OPEN<CLOSE,M)/M >= N/100;
C105 N日内上涨多于下跌 N:=60;//minN:=50,maxN:=100,step:=1
M:=120;//minM:=1,maxM:=300,step:=1
COUNT(CLOSE>REF(CLOSE,1),M)/M >= N/100;
C106 N日内下跌多于上涨 N:=60;//minN:=50,maxN:=100,step:=1
M:=120;//minM:=1,maxM:=300,step:=1
COUNT(CLOSE<REF(CLOSE,1),M)/M >= N/100;
C107 连续N天收阳线 N:=7;//minN:=1,maxN:=100,step:=1
EVERY(CLOSE>OPEN,N);
C108 连续N天收阴线 N:=7;//minN:=1,maxN:=100,step:=1
EVERY(OPEN>CLOSE,N);
C109 首次创新高 BARSSINCE(CLOSE>HHV(IF(BARSCOUNT(CLOSE)=1,HIGH,0),0))+1=1;
C110 单日放量 N:=2;//minN:=1,maxN:=10,step:=1
M:=15;//minM:=1,maxM:=100,step:=1
A1:=MA(VOL,5);
A2:=REF(A1,1);
VOL/A2>N AND 100*VOL/CAPITAL>M;
C111 阶段缩量 N:=10;//minN:=1,maxN:=100,step:=1
M:=5;//minM:=1,maxM:=100,step:=1
0.01*SUM(VOL,N)/CAPITAL<=M;
C112 阶段放量 N:=10;//minN:=1,maxN:=100,step:=1
M:=15;//minM:=1,maxM:=100,step:=1
0.01*SUM(VOL,N)/CAPITAL>=M;
C113 持续放量 M:=3;//minM:=1,maxM:=100,step:=1
EVERY(VOL>=REF(VOL,1),M);
C114 持续缩量 M:=3;//minM:=1,maxM:=100,step:=1
COUNT(VOL<=REF(VOL,1),M)=M;
C115 间隔放量 N:=30;//minN:=20,maxN:=60, step:=1
N1:=4;//minN1:=0,maxN1:=100, step:=1
N2:=2;//minN2:=1,maxN2:=100, step:=1
N3:=3;//minN2:=1,maxN2:=100, step:=1
A:=MA(VOL,5);
BARSCOUNT(CLOSE)>=N AND HHV(A,N)<N1*LLV(A,N) 
AND COUNT(VOL>N2*A,N)>N3;
C116 放量上攻 N:=1;//minN:=0,maxN:=10, step:=1
N1:=3;//minN1:=0,maxN1:=10, step:=1
N2:=20;//minN2:=1,maxN2:=1000, step:=1
N3:=5;//minN2:=1,maxN2:=100, step:=1
A:= (CLOSE-REF(CLOSE,1))/REF(CLOSE,1)>=(N/100);
100*SUM(VOL,N1)/CAPITAL>=N2 
AND COUNT(VOL>REF(VOL,1),N3)=N3 AND  COUNT(A,N3)=N3;
C117 温和放量上攻 N:=5;//minN:=2,maxN:=10, step:=1
N1:=10;//minN1:=1,maxN1:=40, step:=1
A1:=CLOSE/REF(CLOSE,1);
A2:=A1>1 AND A1<1.03;
{股价小幅上扬}
B1:=VOL/REF(VOL,1);
B2:=B1>1 AND B1<2;
C1:=100*MA(VOL,N)/CAPITAL<5;
{成交量小幅上扬}
COUNT(A2 AND B2,N)/N>0.6 AND C1;
C118 突然放量 N:=10;//minN:=1,maxN:=300, step:=1
M:=3;//minM:=1,maxN1:=40, step:=1
VOL>REF(HHV(VOL,N),1)*M;
C119 平台整理 N:=30;//minN:=1,maxN:=100, step:=1
N1:=11;//minN1:=1,maxN1:=100, step:=1
COUNT(CLOSE,0)>N AND 
(HHV(CLOSE,N)-LLV(CLOSE,N))/LLV(CLOSE,N)<=(N1/100);
C120 尾盘打压 N:=2;//minN:=0,maxN:=20, step:=1
TIME>145600 AND CLOSE/REF(CLOSE,2) <= 1-N/100;
C121 尾盘拉升 N:=2;//minN:=0,maxN:=20, step:=1
TIME>145600 AND CLOSE/REF(CLOSE,2) >= 1+N/100;
C122 盘中逆势走强股 N:=930;//minN:=930,maxN:=1500,step:=1
M:=1030;//minM:=930,maxM:=1400,step:=1
A:=HHV(IF(TIME=N,INDEXC,0),0);
B:=HHV(IF(TIME=M,INDEXC,0),0);
D:=HHV(IF(TIME=N,CLOSE,0),0);
E:=HHV(IF(TIME=M,CLOSE,0),0);
E/D>B/A;
C123 突破长期盘整 N:=30;//minN:=10,maxN:=60, step:=1
N1:=5;//minN1:=5,maxN1:=50, step:=1
REF(((HHV(HIGH,N)-LLV(LOW,N))/LLV(LOW,N)),1)<=(N1/100) 
 AND CLOSE>=REF(HHV(HIGH,N),1) AND BARSCOUNT(CLOSE)>N;
 
C124 阶段强势股 N:=1000101;//minN:=900101,maxN:=1501231, step:=1
N1:=1000631;//minN1:=900101,maxN1:=1501231, step:=1
A:=SUM(IF(DATE-N=0,INDEXC,0),0);
B:=SUM(IF(DATE-N1=0,INDEXC,0),0);
E:=SUM(IF(DATE-N=0,CLOSE,0),0);
F:=SUM(IF(DATE-N1=0,CLOSE,0),0);
((F-E)/E)>((B-A)/A);
 
C125 阶段弱势股 N:=1000101;//minN:=900101,maxN:=1501231, step:=1
N1:=1000631;//minN1:=900101,maxN1:=1501231, step:=1
A:=SUM(IF(DATE=N,INDEXC,0),0);
B:=SUM(IF(DATE=N1,INDEXC,0),0);
E:=SUM(IF(DATE=N,CLOSE,0),0);
F:=SUM(IF(DATE=N1,CLOSE,0),0);
((F-E)/E)<((B-A)/A);
C126 大盘同步选股 选择当天某一时段中走势强于大盘的股票
N:=10;//minN:=1,maxN:=100, step:=1
M:=50;//minM:=5,maxN1:=100, step:=1
COUNT((CLOSE>OPEN AND INDEXC>INDEXO) OR (CLOSE<OPEN AND INDEXC<INDEXO),N)/N>M/100;
 
C127 N日内强势股 N:=20;//minN:=1,maxN:=100, step:=1
M:=3;//minM:=1,maxN1:=100, step:=1
GG:=(CLOSE-REF(OPEN,N))/REF(OPEN,N);
DP:=(INDEXC-REF(INDEXO,N))/REF(INDEXO,N);
QSG:GG/DP>=M;
 
CSFR
出水芙蓉 S:=20;//minS:=1,maxS:=60, step:=1
M:=40;//minM:=1,maxN1:=60, step:=1
N:=60;//minN:=1,maxN:=60, step:=1
A:=CLOSE>OPEN;
B:=A AND CLOSE>MA(CLOSE,S) AND CLOSE>MA(CLOSE,M) AND CLOSE>MA(CLOSE,N);
CS:=B AND OPEN<MA(CLOSE,M) AND OPEN<MA(CLOSE,N);
CSFR:CS AND (CLOSE-OPEN)>0.0618*CLOSE;
 
DDE金叉 DDX、DDY还有DDZ同时金叉 N1:=60;//minN1:=0,maxN1:=1000, step:=1
N2:=5;//minN2:=0,maxN2:=1000, step:=1
N3:=10;//minN2:=0,maxN2:=1000, step:=1
P1:=5;//minP1:=0,maxP1:=1000, step:=1
P2:=5;//minP2:=0,maxP2:=1000, step:=1
P3:=10;//minP2:=0,maxP2:=1000, step:=1
DDX:((ZLZJ(8)+ZLZJ(2))-(ZLZJ(11)+ZLZJ(5)))/FINANCE(7),COLORSTICK;
DDX1:EMA(DDX,N1);
DDX2:MA(DDX1,N2);
DDX3:MA(DDX1,N3);
DDY:(ZLZJ(26)-ZLZJ(25))*10000/FINANCE(7),COLORSTICK;
DDY1:EMA(DDY,P1);
DDY2:MA(DDY1,P2);
DDY3:MA(DDY1,P3);
DDZ:(ZLZJ(26)-ZLZJ(25))/(ZLZJ(26)+ZLZJ(25))*170;
DDZ1:(ZLZJ(26)-ZLZJ(25))/(ZLZJ(26)+ZLZJ(25))*30;
FILLRGN(DDZ,DDZ1,DDZ>DDZ1,RGB(255,0,0),DDZ<DDZ1,RGB(0,255,0),DDZ=DDZ1,RGB(255,0,0) );
JC1:=DDX1>DDX2, DDX2>DDX3, DDX>0.6;
JC2:=DDY1>DDY2, DDY2>DDY3;
JC3:=DDZ>15;
XG:JC1 AND JC2 AND JC3;
 
DDX金叉 DDX1与DDX2和DDX3形成金叉 N1:=60;//minN1:=0,maxN1:=1000, step:=1
N2:=5;//minN2:=0,maxN2:=1000, step:=1
N3:=10;//minN2:=0,maxN2:=1000, step:=1
DDX:((ZLZJ(8)+ZLZJ(2))-(ZLZJ(11)+ZLZJ(5)))/FINANCE(7),COLORSTICK;
DDX1:EMA(DDX,N1);
DDX2:MA(DDX1,N2);
DDX3:MA(DDX1,N3);
A1:CROSS(DDX1,DDX2);
A2:CROSS(DDX1,DDX2);
A1 AND A2;
 
DDX量倍增 今日的DDX数值对应昨天DDX的数值N倍 DDX量倍增今日的DDX数值对应昨天DDX的数值N倍
N:=3;//minN:=1,maxN:=1000,step:=1
P3:=( ZLZJ(25)- ZLZJ(26))*VOL;
DDX:=P3/ FINANCE(7) *100;
DDX/REF(DDX,1)>=N AND DDX>=0;
 
DOWNN 连跌数天 N:=3;//minN:=1,maxN:=50,step:=1
DOWN3:DOWNWARD(CLOSE,N);
DTPL 均线多头排列 N:=5;//minN:=1,maxN:=500,step:=1
N1:=10;//minN1:=1,maxN1:=500, step:=1
N2:=20;//minN2:=1,maxN2:=500, step:=1
N3:=30;//minN2:=1,maxN2:=500, step:=1
A1:=MA(CLOSE,N);
A2:=MA(CLOSE,N1);
A3:=MA(CLOSE,N2);
A4:=MA(CLOSE,N3);
COUNT(A1>A2 AND A2>A3 AND A3>A4,3)=3 AND CLOSE>OPEN;
 
KTPL 均线空头排列 均线系统呈空头排列,这时的形势不利与多方迅速组织起强有力的反攻.
N:=5;//minN:=1,maxN:=500,step:=1
N1:=10;//minN1:=1,maxN1:=500, step:=1
N2:=20;//minN2:=1,maxN2:=500, step:=1
N3:=30;//minN2:=1,maxN2:=500, step:=1
A1:=MA(CLOSE,N);
A2:=MA(CLOSE,N1);
A3:=MA(CLOSE,N2);
A4:=MA(CLOSE,N3);
COUNT(A1<A2 AND A2<A3 AND A3<A4,3)=3 AND CLOSE<OPEN;
 
GREEN4 四串阴 STAR:EVERY(CLOSE<OPEN AND OPEN>REF(CLOSE,1),4);
RED4 四串阳 A:EVERY(CLOSE>OPEN AND OPEN<REF(CLOSE,1),4);
KDJ买入 随机指标买入条件选股 N1:=9;//minN1:=2,maxN1:=100, step:=1
N2:=3;//minN2:=2,maxN2:=40, step:=1
N3:=3;//minN2:=2,maxN2:=40, step:=1
RSV:=(CLOSE-LLV(LOW,N1))/(HHV(HIGH,N1)-LLV(LOW,N1))*100;
K:=SMA(RSV,N2,1);
D:=SMA(K,N3,1);
J:=3*K-2*D;
CROSS(J,0);
 
KDJ卖出 随机指标卖出条件选股 KDJ指标共绘制三条线,其中:J线向下突破零线,卖出信号
N1:=9;//minN1:=1,maxN1:=100, step:=1
N2:=3;//minN2:=1,maxN2:=100, step:=1
N3:=3;//minN2:=1,maxN2:=100, step:=1
RSV:=(CLOSE-LLV(LOW,N1))/(HHV(HIGH,N1)-LLV(LOW,N1))*100;
K:=SMA(RSV,N2,1);
D:=SMA(K,N3,1);
J:=3*K-2*D;
CROSS(100,J);
 
MACD买入 MACD买入点条件选股 分析MACD柱状线,由绿变红(负变正),买入信号。DIFF与DEA形成金叉时为买入信号.
SHORT:=12;//minSHORT:=5,maxSHORT:=50,step:=1
LONG:=26;//minLONG:=20,maxLONG:=100,step:=1
M:=9;minM:=2,maxM:=40,step:=1
DIFF := EMA(CLOSE,SHORT) - EMA(CLOSE,LONG);
DEA  := EMA(DIFF,M);
CROSS(DIFF,DEA);
 
MACD卖出 MACD卖出条件选股 分析MACD柱状线,由红变绿(正变负),卖出信号。DEA与DIFF形成死叉时为卖出信号.
SHORT:=12;//minSHORT:=5,maxSHORT:=50,step:=1
LONG:=26;//minLONG:=20,maxLONG:=100,step:=1
M:=9;minM:=2,maxM:=40,step:=1
DIFF := EMA(CLOSE,SHORT) - EMA(CLOSE,LONG);
DEA  := EMA(DIFF,M);
CROSS(DEA ,DIFF);
 
MA买入 均线买入条件选股 短期均线从下向上穿越长期均线.
短期均线参数为SHORT,长期均线参数为LONG
SHORT:=5;//minSHORT:=1,maxSHORT:=100,step:=1
LONG:=10;//minLONG:=2,maxLONG:=300,step:=1
CROSS(MA(CLOSE,SHORT),MA(CLOSE,LONG));
MA卖出 均线卖出条件选股 长期均线从上往下交叉短期均线为卖出信号.
N:=10;minN:=1,maxN:=100,step:=1
M:=30;minM:=2,maxM:=300,step:=1
CROSS(MA(CLOSE,M),MA(CLOSE,N));
MSTAR
早晨之星 STAR:REF(CLOSE,2)/REF(OPEN,2)<0.95 AND
REF(OPEN,1)<REF(CLOSE,2) AND 
ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.03 AND
CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2);
 
MTM买入 MTM买入条件选股 N:=6;minN:=1,maxN:=50,step:=1
IMTM:CROSS(MA(CLOSE-REF(CLOSE,N),N),0);
MTM卖出 MTM卖出条件选股 MTMMA向下突破零,卖出信号
N1:=6;//minN1:=1,maxN1:=100, step:=1
N2:=6;//minN2:=1,maxN2:=100, step:=1
CROSS(0,MA(CLOSE-REF(CLOSE,N),N1));
NHIGH 近日创历史新高 历史的新高,既反映了行情的火爆,也提醒投资者小心见顶回落的必要
N:=3;//minN:=1,maxN:=60, step:=1
HHV(HIGH,N)=HHV(HIGH,0);
NLOW 近日创历史新低 历史新低,既反映了行情的冷淡,也提醒投资者关注市场底部的到来
N:=3;//minN:=1,maxN:=60, step:=1
LLV(LOW,N)=LLV(LOW,0);
PRD 穿透率(大于) P1:=40;//minP1:=0,maxP1:=100, step:=1
PR:(WINNER(CLOSE)-REF(WINNER(CLOSE),1))>P1*VOL/CAPITAL;
PRX 穿透率(小于) P1:=-40;//minP1:=-100,maxP1:= 0, step:=1
PR:(WINNER(CLOSE)-REF(WINNER(CLOSE),1))<P1*VOL/CAPITAL;
QSZL 强势整理 强势整理:一根实体超过5%的长阳,后面跟2个振幅不超过1.5%的K线
N:=5;//minN:=1,maxN:=20, step:=1
M:=2;//minM:=1,maxN1:=20, step:=1
A1:=ABS(CLOSE-OPEN)/OPEN<0.015;
A2:=COUNT(A1,M)=M;
A3:=REF(OPEN,M)<REF(CLOSE,M) AND 
REF(CLOSE,M)/REF(CLOSE,M+1)>1+N/100;
A2 AND A3;
QTDS 蜻蜓点水 个股跌破年线后并未大幅下滑,仅仅在年线处短暂停留便如弹簧般迅速弹起,犹如蜻蜓般掠过湖面,这是一个可靠的买入信号
N:=120;//minN:=20,maxN:=250, step:=1
BUY1:=LAST(CLOSE>MA(CLOSE,N),0,5);
BUY2:=EXIST(CLOSE<MA(CLOSE,N),5);
BUY:CLOSE>MA(CLOSE,N) AND BUY1 AND BUY2;
RSI买入 RSI买入条件选股 N:=6;//minN:=2,maxN:=100, step:=1
LL:=40;//minLL:=0,maxLL:=100, step:=1
LC:= REF(CLOSE,1);
RSI1:=SMA(MAX(CLOSE-LC,0),N,1)/SMA(ABS(CLOSE-LC),N,1)*100;
CROSS(RSI1,LL);
RSI卖出 RSI卖出条件选股 RSI从高位区域下跌,预示股价高,有回调要求.
N:=6;//minN:=2,maxN:=100, step:=1
LL:=80;//minLL:=0,maxLL:=100, step:=1
LC := REF(CLOSE,1);
RSI1:=SMA(MAX(CLOSE-LC,0),N,1)/SMA(ABS(CLOSE-LC),N,1)*100;
CROSS(LL,RSI1);
SAR买入 抛物转向买入条件选股 N:=10;//minN:=1,maxN:=50, step:=1
STEP:=2;//minSTEP:=1,maxSTEP:=5, step:=1
MAXP:=20;//minMAXP:=5,maxMAXP:=80, step:=1
SARTURN(N,STEP,MAXP)=1;
SAR卖出 抛物转向卖出条件 N:=10;//minN:=1,maxN:=50, step:=1
STEP:=2;//minSTEP:=1,maxSTEP:=5, step:=1
MAXP:=20;//minMAXP:=5,maxMAXP:=80, step:=1
SARTURN(N,STEP,MAXP)=-1;
SP 低点搜寻 N:=5;//minN:=1,maxN:=20, step:=1
W:=MA((LLV(LOW,45)-CLOSE)/(HHV(HIGH,45)-LLV(LOW,45))*100,N);
CROSS(-5,W);
 
SWORD 出鞘利剑,冲破了空头束缚的阴影
A:=VOL>REF(VOL,1) OR VOL>CAPITAL;
B:=OPEN>=(REF(HIGH,1))AND REF(HIGH,1)>(REF(HIGH,2)*1.06);
C:=CLOSE>(REF(CLOSE,1))-(REF(CLOSE,1)*0.01);
D:=CLOSE<(HIGH*0.965) AND HIGH>(OPEN*1.05);
E:=LOW<OPEN AND LOW<CLOSE AND  HIGH>(REF(CLOSE,1)*1.06);
F:=(HIGH-(MAX(OPEN,CLOSE)))/2>(MIN(OPEN,CLOSE))-LOW;
G:=(ABS(OPEN-CLOSE))/2<(MIN(OPEN,CLOSE)-LOW);
STAR:A AND B AND C AND D AND E AND F AND G;
 
TLFZ 天量法则 量于价先行,冲天大量,预示了行情的好转
STAR:CLOSE>OPEN AND HHV(CLOSE,50)=CLOSE AND DYNAINFO(37)>0.15 AND 
DYNAINFO(13)<0.14;
 
UPN 连涨数天 N:=3;//minN:=1,maxN:=50, step:=1
UP3:UPWARD(CLOSE,N);
W-103 高开大阴线 收盘为高开大阴线:跳空高开m%,当日股价较开盘价跌幅大于n%
N:=5;minN:=1,maxN:=20,step:=1
M:=4;minM:=1,maxM:=10,step:=1
OPEN/REF(CLOSE,1)>=1+M/100 AND CLOSE/OPEN<=1-N/100;
W-104 低开大阳线 收盘为低开大阳线:今日低开m% 且收盘价相对开盘价上涨大于n%,
N:=7;minN:=1,maxN:=20,step:=1
M:=4;minM:=1,maxM:=10,step:=1
OPEN/REF(CLOSE,1)<=1-M/100 AND CLOSE/OPEN>=1+N/100;
W-105 跳空缺口选股 HIGH<REF(LOW,1) OR LOW>REF(HIGH,1);
 
WR买入 威廉指标买入条件选股 N:=14;minN:=2,maxN:=100,step:=1
LL:=80;minLL:=60,maxLL:=100,step:=1
WR:=100*(HHV(HIGH,N)-CLOSE)/(HHV(HIGH,N)-LLV(LOW,N));
CROSS(LL,WR);
WR卖出 威廉指标卖出条件选股 威廉指标向下突破某一区域(20)为卖出信号
N:=14;minN:=1,maxN:=100,step:=1
M:=20;minM:=1,maxM:=100,step:=1
WR:=100*(HHV(HIGH,N)-CLOSE)/(HHV(HIGH,N)-LLV(LOW,N));
CROSS(M,WR);
XRDS 旭日初升 长期潜伏于年线之下的股票,终于露出了行动的痕迹
N:=120;minN:=20,maxN:=250,step:=1
BUY1:=LAST(CLOSE<MA(CLOSE,N),0,5);
BUY:CLOSE>MA(CLOSE,N) AND VOL>MA(VOL,5)*2 AND BUY1;
大换手率 每天换手3%-15%之间的股票 VAR1:=100*VOL/CAPITAL;
W1:=VAR1>3;
W2:=VAR1<15;
XG:W1 AND W2;
 
大阳穿线 大阳穿线 1根大阳线同一天涨穿P1、P2、P3,3根均线成交量放大
P:=5;minP1:=1,maxN:=999,step:=0.5
P:=10;minP2:=1,maxN:=999,step:=0.5
P:=20;minP3:=1,maxN:=999,step:=0.5
N:=1.5;minN:=1,maxN:=999,step:=0.5
XG:CROSS(C,MA(C,P1)) AND CROSS(C,MA(C,P2)) AND CROSS(C,MA(C,P3)) AND V>REF(V,1)*1.1 AND V<REF(V,1)*N;
 
SSPN 短期超跌 P个交易日内,股价跌幅达到20%的股票:
P:=20;minP3:=1,maxN:=999,step:=1
N:=0.2;minN:=0,maxN:=1,step:=0.01
XG: (HHV(C,P)-C)/HHV(C,P)>N;
均线走平 N:=30;minN:=1,maxN:=999,step:= 1
MA1:=MA(CLOSE,N);
AR1:=MA1>=REF(MA1,2);
AR2:=BARSLAST((C-MA1)/MA1*100<-6);
AR3:=COUNT(CROSS(CLOSE,MA1),AR1)=1;
AR4:=COUNT(CLOSE>MA(CLOSE,N),4)>1;
AR5:=AR1 AND AR2 AND AR3 AND AR4;
XG:AR5 AND FILTER(AR5,10);
P1均线走平或走高
DUBYX 双趋势线
一条上轨一条下轨组成课调整的趋势线组合
P:=30;minP:=1,maxP:=999,step:= 1
HV1:=REF(H,P)=HHV(H,2*P+1);
HV2:=FILTER(HV1,P);
HV3:=BACKSET(HV2,P+1);
HV4:=FILTER(HV3,P);
R11:=BACKSET(BARSTATUS=2,BARSLAST(HV4)+1); 
S11:=R11>REF(R11,1);
BOH:DRAWLINE(HV4,H,S11,H,1),COLORBLUE;
AA2:=REF(L,P)=LLV(L,2*P+1);
BB2:=FILTER(AA2,P);
CC2:=BACKSET(BB2,P+1);
DD2:=FILTER(CC2,P);
T11:=BACKSET(BARSTATUS=2,BARSLAST(DD2)+1);
U11:=T11>REF(T11,1);
 
 
交易策略公式
TEST 经典测试 N:10; //maxN50,minN1
TB:=IF(HIGH>REF(CLOSE,1),HIGH-REF(CLOSE,1)+CLOSE-LOW,CLOSE-LOW);
TS:=IF(REF(CLOSE,1)>LOW,REF(CLOSE,1)-LOW+HIGH-CLOSE,HIGH-CLOSE);
VOL_:=(TB-TS)*VOL/(TB+TS)/10000;
VOL_0:=DMA(VOL_,0.1);
VOL_1:=DMA(VOL_,0.05);
SHORT:=VOL_0-VOL_1,COLORSTICK;
MA1:=MA(SHORT,N);
ENTERLONG:CROSS(SHORT,MA1);
EXITLONG:SHORT<=0;
ENTERSHORT:SHORT>=0;
EXITSHORT:CROSS(MA1,SHORT);
五彩K线指标
DKFX 多空方向
WYGD 乌云盖顶 WYGD:=BACKSET( 
REF(CLOSE,1)/REF(OPEN,1)>1.03 AND 
CLOSE/OPEN<0.97 AND 
OPEN>REF(CLOSE,1) AND CLOSE<REF(CLOSE,1), 3);
DRAWKLINEEX(WYGD,H,O,L,C),COLOR0000FF;
DRAWKLINEEX(NOT(WYGD),H,O,L,C),COLORFFFF00;
SGCX 曙光初现 SGCX:=BACKSET(
REF(CLOSE,1)/REF(OPEN,1)<0.97 AND
CLOSE/OPEN>1.03 AND
OPEN<REF(CLOSE,1) AND
CLOSE>REF(CLOSE,1), 2);
DRAWKLINEEX(SGCX,H,O,L,C),COLOR0000FF;
DRAWKLINEEX(NOT(SGCX),H,O,L,C),COLORFFFF00;
PTXP 平台下破 PTHIGH:=REF(HHV(CLOSE,9),1);
PTLOW:=REF(LLV(CLOSE,9),1);
PTEXIST:=(PTHIGH-PTLOW)/CLOSE<0.05;
TPEXIST:=CLOSE<PTLOW*0.99;
PTXP:=PTEXIST AND TPEXIST;
DRAWKLINEEX(PTXP,H,O,L,C),COLOR0000FF;
DRAWKLINEEX(NOT(PTXP),H,O,L,C),COLORFFFF00;
PINGDI 平底线 PINGDI:=BACKSET((ABS(LOW-REF(LOW,1))/LOW<0.001 AND
ABS(REF(LOW,1)-REF(LOW,2))/REF(LOW,1)<=0.001),2);
DRAWKLINEEX(PINGDI,H,O,L,C),COLOR0000FF;
DRAWKLINEEX(NOT(PINGDI),H,O,L,C),COLORFFFF00;
 


------分隔线----------------------------
操盘手选拔
友情提示:模拟选拔有难度,做到独立思考决策,不频繁交易。
@2017 DIQIB 操盘手联盟工作室,欢迎您的加入,携手共创美好明天。
软件下载